SUMIF (S) с VLOOKUP

Question

Я пытаюсь использовать функцию VLOOKUP с функцией sumif.

У меня есть раскрывающийся список с списком имен в сочетании со списком комбинаций.

например:

Salesman1 
Salesman2 
Salesman3 
Salesman4 
Salesman5 
Salesman6 
RegionA 
RegionB

и тумбочка, которая имеет список продавцов и regoins: например:

RegionA Salesman1 
RegionB Salesman2 
RegionB Salesman3 
RegionB Salesman4 
RegionA Salesman5 
RegionB Salesman6

(Этот список может быть выгружена в случае необходимости)

I хотелось бы суммировать итоги продажщиков в регионах. Я могу предположить, что с помощью индивидуальных продавцов

=SUMIFS(Data,$C$C,DateTest,$D$D,Salesman Value) 

, но я хотел бы видеть сумму по региону. Данные поступают из другого места, и имеет переменную длину, так что вспомогательный столбец будет трудно создать

Я думал что-то вдоль линий ВПР, но я не могу заставить его работать

=SUMIFS(Data,$C$C,DateTest,$D$D,ISNA(VLOOKUP(Salesman Value,Table!Regions,2,FALSE))) 

уточнение: раскрывающийся содержит как продавцы и регионы, и я хочу, чтобы иметь возможность суммировать оба пути (формула разделения для ясности)

IF(UPPER(LEFT($B$3,3))="REG", 
    SUMIFS(Sheet1!$H:$H,Sheet1!$J:$J,RegionTest,Sheet1!$G:$G,TEXT($E18,"yyyy-mm")), 
    SUMIFS(Sheet1!$H:$H,Sheet1!$J:$J,$B$3,Sheet1!$G:$G,TEXT($E18,"yyyy-mm"))) 

Answer 1

Вы можете использовать формулу массива, как это для «региональных веб»:

=SUM(SUMIFS(Data,$C:$C,DateTest,$D:$D,IF(Regions="RegionA",Salesmen)))

подтвердил CTRL + SHIFT + ENTER

где Регионы и продавщица представляют две колонки вашей таблицы

Edit:

С вашей оговоркой для использования продавцом или регионом попробуйте сделать это

=SUM(SUMIFS(Sheet1!$H:$H,Sheet1!$J:$J,IF(LEFT($B$3,3)="Reg",IF(Regions=$B$3,Salesmen),$B$3),Sheet1!$G:$G,TEXT($E18,"yyyy-mm")))

все еще использует CTRL +SHIFT + ENTER