Как переписать этот блок eval

Question

Этот код пахнет ... как его переписать лучше?

my $record; 

eval { 
    while (
     # undef $record here, so if getRecord() failed, nothing will be written 
     # in the reject file 
     do { undef $record; defined($record = $dataFile->getRecord) } 
    ) { 
     $LT_DataFile->encode($record); 
    } 
    1; 
}; 

if (my $error = $@) { 
    $rejectFile->writeRecord($error, $record); 
} 

Спасибо.

Answer 1

Хорошо, переработал мой ответ.

Я думаю, что проблема заключается в том, как вы справляетесь с ошибками. На первый взгляд сбивает с толку, чтобы увидеть один обработчик ошибок, когда у вас есть несколько мест, где все может пойти не так. Я вижу две альтернативы.

Во-первых, держать его в основном такой же, как у вас есть сейчас, но конкретно проверить для каждого типа ошибок:

my $record; 
eval { 
    while (defined($record = $dataFile->getRecord)) { 
     $LT_DataFile->encode($record); 
    } 
}; 
if (my $error = $@) { 
    given ($error) { 
     when (/get record error/) { $rejectFile->writeRecord($_, undef); } 
     when (/encode error/)  { $rejectFile->writeRecord($_, $record); } 
    } 
} 

Таким образом, вы явно в том, как вы справляетесь свои ошибки. Конечно, с Try :: Крошечный, это упрощает в следующем

my $record; 
try { 
    while (defined($record = $dataFile->getRecord)) { 
     $LT_DataFile->encode($record); 
    } 
} catch { 
    when (/get record error/) { $rejectFile->writeRecord($_, undef); } 
    when (/encode error/)  { $rejectFile->writeRecord($_, $record); } 
} 

В качестве альтернативы, вы можете добавить лексическую запись в Daxim's answer. Это требует второго Eval или попытаться, ближе к проблеме и добавления last вызова:

eval { 
    while (defined(my $record = $dataFile->getRecord)) { 
     eval { $LT_DataFile->encode($record) }; 
     if (my $error = $@) { $rejectFile->writeRecord($error, $record); last } 
    } 
}; 
if (my $error = $@) { 
    $rejectFile->writeRecord($error, undef); 
} 

К сожалению, этот метод не будет работать с Try :: Крошечными, так как блоки, передаваемые попробовать на самом деле subrefs.

Answer 2

Вам не нужна переменная в ловушке, потому что при ее поступлении ее содержимое всегда будет undef. Замена этого значения с литеральным значением позволяет нам ограничить $record до меньшего объема.

use Try::Tiny; 
try { 
    while (defined(my $record = $dataFile->getRecord)) { 
     $LT_DataFile->encode($record); 
    } 
} catch { 
    $rejectFile->writeRecord($_, undef); # T::T puts error in $_ 
} 

Answer 3

Я бы реорганизовать цикл while к

while (defined($record = $dataFile->getRecord)) { 
    $LT_DataFile->encode($record); 
} continue { 
    undef $record; 
} 

continue блок выполняется после каждой итерации, прежде чем условно проверяется. Он все равно будет вызываться, если ваш код использует next, чтобы начать следующую итерацию раньше. Если вы не вероятно, вызвать next то упростить код

while (defined($record = $dataFile->getRecord)) { 
    $LT_DataFile->encode($record); 
    undef $record; 
} 

будет работать.