удалить атрибут на узле документа

Мне нужно удалить xsi: schemaLocation, но я не получаю его на работу, Я думаю, что я делаю что-то не так в wt: Envelope/wt: Body/wt: MessageParts/* [not (имя() = 'XSI: SchemaLocation')] определение, но не знаю, как решить этот источникудалить атрибут на узле документа

XML:

<?xml version="1.0" encoding="UTF-8"?> 
<Envelope xmlns="http://schemas.microsoft.com/dynamics/2011/01/documents/Message"> 
    <Header> 
    <MessageId>{AAE4C191-6D18-4823-A29D-9C6CA68113C2}</MessageId> 
    <Action>http://tempuri.org/VendPaymentsService/find</Action> 
    </Header> 
    <Body> 
    <MessageParts xmlns="http://schemas.microsoft.com/dynamics/2011/01/documents/Message"> 
    <Document xsi:schemaLocation="urn:iso:std:iso:20022:tech:xsd:pain.001.001.03 pain.001.001.03.xsd" 
      xmlns="urn:iso:std:iso:20022:tech:xsd:pain.001.001.03" 
      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 
     <CstmrCdtTrfInitn> 
      .... 
     </CstmrCdtTrfInitn> 
     </Document> 
    </MessageParts> 
    </Body> 
</Envelope>

Мой XSLT

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:wt="http://schemas.microsoft.com/dynamics/2011/01/documents/Message" 
       xmlns:s1="http://schemas.microsoft.com/dynamics/2008/01/documents/VendPayments" 
       version="1.0"> 
    <xsl:output method="xml" encoding="iso-8859-1" /> 
    <xsl:template match="/"> 
    <xsl:text disable-output-escaping="yes">&lt;?xml version="1.0" encoding="utf-8"?&gt;</xsl:text> 
    <xsl:copy-of select="wt:Envelope/wt:Body/wt:MessageParts/*[not(name() ='xsi:schemaLocation')]" /> 
    </xsl:template> 
</xsl:stylesheet>

результат

<?xml version="1.0" encoding="utf-8"?> 
<Document 
xsi:schemaLocation="urn:iso:std:iso:20022:tech:xsd:pain.001.001.03 pain.001.001.03.xsd" xmlns="urn:iso:std:iso:20022:tech:xsd:pain.001.001.03" 
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 
<CstmrCdtTrfInitn> 
.. 
</CstmrCdtTrfInitn> 
</Document>

Что я делаю неправильно?

источник

2014-11-02 dick wenning

Какой результат вы пытаетесь получить? Вы хотите элемент '' и его дочерние элементы без атрибута 'xsi: schemaLocation'? –

<xsl:copy-of> выполняет глубокую копию; вы не можете исключить отдельные узлы. Отметим также, что xsi:schemaLocation является атрибутом , а не элементом .

Попробуйте это, возможно?

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:wt="http://schemas.microsoft.com/dynamics/2011/01/documents/Message" 
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/"> 
    <xsl:apply-templates select="wt:Envelope/wt:Body/wt:MessageParts/*" /> 
</xsl:template> 

<xsl:template match="@xsi:schemaLocation"/> 

</xsl:stylesheet>

Примечание:
Вы должны никогда требуется использовать хак вроде этого:

<xsl:text disable-output-escaping="yes">&lt;?xml version="1.0" encoding="utf-8"?&gt;</xsl:text>

Если вы хотите, чтобы ваш выход иметь кодировку UTF-8, так сказать в <output> элемент.

источник

2014-11-02 15:16:50

удалить атрибут на узле документа

ответ

Смежные вопросы