Как нарисовать прозрачность с альфа-прозрачностью в Delphi?

Question

Я хочу нарисовать довольно сложные изображения с альфа-прозрачными прямоугольниками и альфа-прозрачными изображениями. There is GDI+ wrapper from Mitov, но, похоже, он не поддерживает 32-битные файлы BMP, и он пересказывает их, и документация ужасна. BMP быстрее, чем PNG, поэтому я хочу их использовать. There is SynGDI wrapper of GDI+, но он кажется очень простым, и для него нет документации. Существует также этот трюк для GDI:

procedure DrawAlphaAPI(Source: TBitmap; Destination: TCanvas; 
    const X, Y: Integer; const Opacity: Byte = 255); 
var BlendFunc: TBlendFunction; 
begin 
    BlendFunc.BlendOp := AC_SRC_OVER; 
    BlendFunc.BlendFlags := 0; 
    BlendFunc.SourceConstantAlpha := Opacity; 

    if Source.PixelFormat = pf32bit then 
    BlendFunc.AlphaFormat := AC_SRC_ALPHA 
    else 
    BlendFunc.AlphaFormat := 0; 

    Windows.AlphaBlend(Destination.Handle, X, Y, Source.Width, Source.Height, 
    Source.Canvas.Handle, 0, 0, Source.Width, Source.Height, BlendFunc); 
end; 

Но когда я называю его Opacity = 255 она рисует 32-битные растровые изображения не правильно (что-то, что они являются полупрозрачными, где они должны быть полностью). Я не хочу использовать Scanline, чтобы сделать пикселы прозрачными, поскольку это будет слишком сложно, чтобы рисовать все прозрачные прямоугольники таким образом. Также я тонкий GDI + должен быть быстрее на современных компьютерах, верно?

Итак, вопрос: как рисовать альфа-прозрачный прямоугольник и растровое изображение легко (без тонны кода)?

Предпочитаемый Delphi: 7. У меня также есть 2005 и XE3, но поскольку 7 - демон скорости, я бы больше всего хотел, чтобы что-то работало с 7 до.

Answer 1

Если вы подготовите обычный TBitmap, любую из реализаций GDI + можно использовать, просто назначив bmp.Canvas.Handle. Ваша проблема с компиляцией может быть вызвана старой версией DirctDraw в папке, просто удалите ее.

implementation 

uses GDIPAPI, GDIPOBJ; 
{$R *.dfm} 

Procedure PrepareBMP(bmp: TBitmap; Width, Height: Integer); 
var 
    p: Pointer; 
begin 
    bmp.PixelFormat := pf32Bit; 
    bmp.Width := Width; 
    bmp.Height := Height; 
    bmp.HandleType := bmDIB; 
    bmp.ignorepalette := true; 
    bmp.alphaformat := afPremultiplied; 
    // clear all Scanlines 
    p := bmp.ScanLine[Height - 1]; 
    ZeroMemory(p, Width * Height * 4); 
end; 

procedure TForm2.Button1Click(Sender: TObject); 
var 
    bmp: TBitmap; 
    G: TGPGRaphics; 
    B: TGPSolidBrush; 
begin 
    bmp := TBitmap.Create; 
    try 
    PrepareBMP(bmp, 300, 300); 
    G := TGPGRaphics.Create(bmp.Canvas.Handle); 
    B := TGPSolidBrush.Create(MakeColor(100, 255, 0, 0)); 
    try 
     G.SetSmoothingMode(SmoothingModeHighQuality); 
     G.FillEllipse(B, MakeRect(0.0, 0, 300, 300)); 
     B.SetColor(MakeColor(100, 0, 255, 128)); 
     G.FillEllipse(B, MakeRect(40.0, 40, 260, 260)); 
    finally 
     B.Free; 
     G.Free; 
    end; 
    // draw overlapping in Form Canvas to display transparency 
    Canvas.Draw(0, 0, bmp); 
    Canvas.Draw(100, 100, bmp); 
    finally 
    bmp.Free; 
    end; 
end;