Haskell Рекурсивный тип классов

Question

Я хочу создать рекурсивный тип экземпляра на основе кортежей. Я ищу что-то подобное:

class Provider a b where 
    getInstance :: a -> b 

instance Provider a b => Provider (x, a) b where 
    getInstance (x, a) = getInstance a 

instance Provider (b, x) b where 
    getInstance (b, _) = b 

tryFunc1 :: Int 
tryFunc1 = 
    let provider = ("test", (10,())) :: (String, (Int,())) 
    in getInstance provider 

tryFunc2 :: String 
tryFunc2 = 
    let provider = ("test", (10,())) :: (String, (Int,())) 
    in getInstance provider 

К сожалению, haskell не может решить проблему. Любая причина?

Answer 1

Решение состоит в том, чтобы прекратить использование устаревшей прагмы OverlappingInstances и начать использовать для примера OVERLAPPING и OVERLAPPABLE прагмы. С помощью всего этого изменения:

instance {-# OVERLAPPABLE #-} Provider a b => Provider (x, a) b where 
    getInstance (x, a) = getInstance a 

instance {-# OVERLAPPING #-} Provider (b, x) b where 
    getInstance (b, _) = b 

я tryFunc1 быть 10 и tryFunc2 быть "test".

---

Технически вам нужно только либо в OVERLAPPABLE или OVERLAPPING прагму, но я считаю, что это хорошая практика, чтобы и в этом случае ... Кроме того, я полагаю, что это поведение, которое вы хотите, но обратите внимание, что это просто получает первый любого типа вы ищете (так getInstance (10, (20,())) :: Int дает мне 10 и не20)

Хороший источник информации является ticket отслеживания создания описываемого объекта.

Answer 2

Я знаю, что некоторые люди не любят UndecidableInstances, но это то, что мне нравится делать в этом типе ситуации: используйте закрытый type family, чтобы сделать его явным, чтобы выбор был полностью детерминированным.

Идея состоит в том, чтобы семейство типов вычислило булевский флаг, давая понять, какая ветка должна быть взята механизмом разрешения типа. Расширение UndecidableInstance необходимо из-за ограничения Provider a b (AtHead a b) =>, хотя оно безвредно.

{-# LANGUAGE MultiParamTypeClasses #-} 
{-# LANGUAGE FlexibleInstances  #-} 
{-# LANGUAGE FlexibleContexts  #-} 
{-# LANGUAGE UndecidableInstances #-} 
{-# LANGUAGE TypeFamilies   #-} 
{-# LANGUAGE DataKinds    #-} 
{-# LANGUAGE TypeOperators   #-} 
{-# LANGUAGE ScopedTypeVariables #-} 

module Provider where 

import Data.Proxy 
import Data.Type.Equality 

class Provider a b (f :: Bool) where 
    getInstance' :: Proxy f -> a -> b 

type family AtHead x y :: Bool where 
    AtHead (x, a) y = x == y 

instance Provider a b (AtHead a b) => Provider (x, a) b 'False where 
    getInstance' _ (x, a) = getInstance' (Proxy :: Proxy (AtHead a b)) a 

instance Provider (b, x) b 'True where 
    getInstance' _ (b, _) = b 

getInstance :: forall a b. Provider a b (AtHead a b) => a -> b 
getInstance = getInstance' (Proxy :: Proxy (AtHead a b)) 

tryFunc1 :: Int 
tryFunc1 = 
    let provider = ("test", (10,())) :: (String, (Int,())) 
    in getInstance provider 

tryFunc2 :: String 
tryFunc2 = 
    let provider = ("test", (10,())) :: (String, (Int,())) 
    in getInstance provider