Perl: Добавление в массив хэша

Question

Я пытаюсь добавить значения в массивы в хэш.

foreach my $f (@files) { 
    my $file = "$logDir/$f"; 
    open my $info, $file or die "Could not open $file: $!"; 
    while (my $line = <$info>) { 
    chomp $line; 
    if ($line =~ /CONN.*\[ID=(.*)\].*ID is(.*)/) { 
     $b = $1; 
     $a = $2; 
     $a =~ s/^\s+//; 
     $bHash{$b} = $a if (exists $aHash{$a}); 
    } 
    elsif ($line =~ /succ.*\[ID=(.*)\].*/) { 
     $b = $1; 
     push(@{ $bHash{$b} }, "bSUCC") if (exists $bHash{$b}); 
    } 
    elsif ($line =~ /fail.*\[ID=(.*)\].*/) { 
     $b = $1; 
     push(@{ $bHash{$b} }, "bFAIL") if (exists $bHash{$b}); 
    } 
    } 
    close $info; 
} 

Я связывающие два файла журнал вместе на основе коды транзакции и-х идентификатор транзакции Б, которые оба найдены на одной строке журнала в журнале Б.

Оператор if проверяет это и заполняет %bHash идентификатором b-> ID = a->.

Затем я ищу либо успех, либо неудачу транзакции b. Если я вижу строку успеха, я беру идентификатор транзакции, и если этот идентификатор существует в %bHash, тогда я хочу нажать сообщение «bSucc» в конец массива, то есть %bHash будет иметь bSid -> aSid, bSucc.

Я получаю следующее сообщение об ошибке/предупреждение:

Can't use string ("7747395") as an ARRAY ref while "strict refs" in use at ./report.pl line 54, <$info> line 833. 

Есть ли способ сделать это?

Я также хочу продолжать добавлять информацию в массив, если это возможно, когда я просматриваю журнал для получения дополнительных данных. Я хочу использовать идентификатор транзакции в качестве ключа и просто добавлять информацию по мере необходимости. Это возможно? Есть ли лучший способ выполнить задачу?

Редактировать: То, что я пытаюсь выполнить, состоит в том, чтобы скомпилировать информацию о транзакции через 3 разных файла журнала. Я хочу найти следующее для каждой транзакции: Success of Fail, If failed, где это произошло, в log a, b или c?

Одна транзакция обрабатывается 3 различными приложениями, поэтому 3 разных журнала. К сожалению, идентификатор trans id отличается от приложения a vs apps b и c. Таким образом, я построил хэш со всеми трансформаторами в журнале a, а затем в журнале b есть строка журнала, которая позволяет вам видеть связь между идентификатором передачи, используемым для журнала a и trans id, используемым для журнала b. Вот почему я сопоставляю trans id с b с хешем из журнала a. В конечном счете, я хочу, чтобы информация для каждого transId была упомянута выше, sucs/fail и т. Д.

Answer 1

Проблема в том, что когда вы изначально устанавливаете каждое значение в %bHash, вы устанавливаете его на строковое значение, а не на массив:

 $bHash{$b} = $a if (exists $aHash{$a}); 

Позже вы пытаетесь протолкнуть значение на «массив» разыменовывая его:

 push(@{ $bHash{$b} }, "bSUCC") if (exists $bHash{$b}); 

но поскольку не не массив, просто строка, Perl считает, что вы пытается разыменовать строку int o массив. (Что, я должен отметить, на самом деле потенциально правовой — если $a является строка 'foo', то @$a означает глобальную переменную @foo — но это не рекомендуется, не допускается в рамках use strict, и, очевидно, не то, что вы пытаетесь сделать .. Я упоминаю это только потому, что текст сообщения об ошибке думает, что это функция, которую вы пытаетесь использовать)

исправление просто использовать ссылку на массив, чтобы начать с:

 $bHash{$b} = [$a] if (exists $aHash{$a}); 

так что у вас есть массив, на который вы можете безопасно вводить значения.