символов до первого дочернего узла и после последнего дочернего узла в XSLT

Question

У меня есть следующий XML:

<line> 
     <orig><gap quantity="4" unit="chars" reason="illegible"/> <gap quantity="4" 
     unit="chars" reason="illegible"/> <gap quantity="3" unit="chars" 
     reason="illegible"/> <gap quantity="5" unit="chars" reason="illegible"/> 
     shal <gap quantity="2" unit="chars" reason="illegible"/> <gap 
     quantity="12" unit="chars" reason="illegible"/> </orig> 
</line> 

я хотел бы применить некоторые стили к нему таким образом, что каждый раз, когда существует последовательность узлов в строка, первый узел зазора предваряется левой квадратной скобкой, а за последним узлом следует прямоугольная квадратная скобка. Число точек, взятых из элемента @quantity in, будет отображаться для каждого узла разметки. Так, например, xml выше должен выглядеть следующим образом:

[.... .... .... ....] shal [.. ............]

Я написал шаблон, который добавляет скобки перед первым узлом и после последнего узла, поэтому выглядит это:

[.... .... ... ..... ШЭЛ .. ............]

Мой код XSLT здесь:

<xsl:template match="tei:orig/tei:gap"> 
    <xsl:variable name="max" select="@quantity"/> 
    <xsl:if test="not(preceding-sibling::tei:gap)"> 
     <xsl:text>[</xsl:text> 
    </xsl:if> 
    <xsl:for-each select="1 to $max"> 
     <xsl:text>.</xsl:text> 
    </xsl:for-each> 
    <xsl:if test="not(following-sibling::tei:gap)"> 
     <xsl:text>]</xsl:text> 
    </xsl:if>   
</xsl:template> 

Как обращаться с другими кронштейнами? Я думал, что смогу это сделать, написав шаблон, который применяется к узлу напрямую, увеличив уровень и используя position(), но это просто обертывает каждый набор точек в квадратных скобках вместо того, чтобы только обернуть начало и конец каждой последовательности узлов.

EDIT: Мой оригинальный образец XML был запутанным и неточно объяснял, что мне нужно сделать, поэтому, надеюсь, эта новая деталь поможет в этом отношении.

Answer 1

Если - как вам кажется, вы используете XSLT 2.0, вы можете использовать команду <xsl:for-each-group> для группировки смежных элементов gap. Например, следующая таблица стилей:

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
<xsl:output method="text" encoding="UTF-8" /> 
<xsl:strip-space elements="*"/> 

<xsl:template match="orig"> 
    <xsl:for-each-group select="node()" group-adjacent="boolean(self::gap)"> 
     <xsl:choose> 
      <xsl:when test="current-grouping-key()"> 
       <xsl:text>[</xsl:text> 
        <xsl:for-each select="current-group()"> 
         <xsl:for-each select="1 to @quantity"> 
          <xsl:text>.</xsl:text> 
         </xsl:for-each> 
         <xsl:if test="position()!=last()"> 
          <xsl:text> </xsl:text> 
         </xsl:if> 
        </xsl:for-each> 
       <xsl:text>]</xsl:text> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:value-of select="current-group()" separator=""/> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:for-each-group> 
</xsl:template> 

</xsl:stylesheet> 

применительно к вашей (новый), например, возвратит:

[.... .... ... .....] 
     shal [.. ............] 

Answer 2

Не могли бы вы предоставить более подробную информацию о том, где вы обнаружили проблему? Я просто написал, как например, после XSLT

<?xml version="1.0" encoding="UTF-8" ?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output method="xml" doctype-public="XSLT-compat" omit-xml-declaration="yes" 
encoding="UTF-8" indent="no" /> 
<xsl:strip-space elements="*"/> 
<xsl:template match="/"> 
    <xsl:apply-templates/> 
</xsl:template> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 
<xsl:template match="hi"> 
    <xsl:value-of select="."/> 
</xsl:template> 
<xsl:template match="orig | line"> 
    <xsl:apply-templates/> 
</xsl:template> 
<xsl:template match="gap"> 
<xsl:variable name="max" select="@quantity"/> 
<xsl:text>[</xsl:text> 
<xsl:for-each select="1 to $max"> 
    <xsl:text>.</xsl:text> 
</xsl:for-each> 
<xsl:text>]</xsl:text> 
</xsl:template> 
</xsl:stylesheet> 

При подаче на вход XML

<line> 
    <orig><hi>W</hi>e be <gap quantity="4" unit="chars" reason="illegible"/> 
     ed and moeued of <gap quantity="6" unit="chars" reason="illegible"/> 
    </orig> 
</line> 

следующий вывод производится

We be [....]ed and moeued of [......] 

Я просто не знаю, почему это необходимо чтобы проверить предыдущий и следующий узлы при применении шаблонов к элементу gap, может быть, это просто недоразумение.