Поиск и создание пакетного файла с более чем одним словом

Question

Мне нужна ваша помощь, я довольно новичок в этом типе сценариев, и мне нужна ваша помощь, чтобы попробовать, чтобы этот скрипт функционировал правильно.

У меня есть сценарий, который ищет папку для файлов и перемещает их в имя папки после первых символов файлов. Но у меня проблема, когда файлы разделены более чем одним.

setlocal EnableDelayedExpansion 
set "IncomingFolder=D:\Test" 
set "showsFolder=D:\Test\" 

for %%F in ("%incomingFolder%\*.S*.*") do ( for /f "delims=.S" %%A in ("%%~nF") do (
if not exist "%showsFolder\%" md "%showsFolder%\%%A" 
move "%%F" "%showsFolder%\%%A" )) 

Например: Если файлы Hustle.SXX.XXX Затем он делает правильную папку с именем «Хастл». Но если он назван The.Hustle.SXXX.XXX, тогда он создает только папку «The», мне нужно использовать это имя до «.S».

Кто-нибудь, кто может мне помочь?

Answer 1

Это использует вспомогательный командный файл repl.bat - скачать с: https://www.dropbox.com/s/qidqwztmetbvklt/repl.bat

Место repl.bat в той же папке, что и командный файл, или в папке, находящейся на пути.

Испытание это, чтобы увидеть, как она идет:

@echo off 
set "IncomingFolder=D:\Test" 
set "showsFolder=D:\Test" 

for %%F in ("%incomingFolder%\*.S*.*") do (
    for /f "delims=" %%A in (' echo "%%~nF"^|repl ".(.*)S\d\d.*" "$1" ') do (
     md "%showsFolder%\%%A" 2>nul 
     move "%%F" "%showsFolder%\%%A" 
    ) 
) 

Answer 2

@ECHO OFF 
SETLOCAL 
set "IncomingFolder=c:\sourcedir" 
set "showsFolder=D:\Test" 

for %%F in ("%incomingFolder%\*.S*.*") do (for /f "delims=." %%A in ("%%~nF") do (
ECHO md "%showsFolder%\%%A" 
ECHO move "%%F" "%showsFolder%\%%A\" 
) 
) 

GOTO :EOF 

Я изменил имена каталогов в соответствии с моей системой.

я не мог воссоздать эту проблему, вы можете описать, но delims=.S бы разделители .илиS, не .S. Это может быть то, что вы видите.

Необходимые команды MD - это всего лишь ECHO ed для целей тестирования. После того, как вы подтвердите правильность команд, измените ECHO MD на MD, чтобы фактически создать каталоги. Добавить 2>nul для подавления сообщений об ошибках (например, когда каталог уже существует)

Кроме того, требуемые команды MOVE являются просто ECHO ed для целей тестирования. После того, как вы подтвердите правильность команд, измените значение ECHO MOVE на MOVE, чтобы на самом деле переместить файлы. Добавить >nul для подавления сообщений отчета (например, 1 file moved)

Answer 3

Вы не можете использовать FOR/F для анализа из-за фронта, потому что вы не знаете, сколько . может отображаться в названии. Я предполагаю, что вы ожидаете таких имен, как part1.part2.Spart3.part4, но не как part1.part2.Spart3.part4.part5. Другими словами - вам не нужны две точки после .S. Если да, то вы можете безопасно удалить все после второй до последней точки. Это легко сделать с помощью модификатора ~n дважды.

for %%F in ("%incomingFolder%\*.S*.*") do for %%A in ("%%~nF") do (
    if not exist "%showsFolder%\%%~nA" md "%showsFolder%\%%~nA" 
    move "%%F" "%showsFolder%\%%~nA\" 
) 

(щекотал Magoo - % отсутствует на «входящие» и ~n требуется вселения назначения)

Answer 4

setlocal EnableDelayedExpansion 
set "IncomingFolder=D:\Test" 
set "showsFolder=D:\Test" 

for %%F in ("%incomingFolder%\*.S*.*") do (
    set "file=%%~nF" 
    for /F "delims=" %%A in ("!file:*.S=!") do set "folder=!file:.S%%~A=!" 
    if not exist "%showsFolder%\!folder!" md "%showsFolder%\!folder!" 
    move "%%F" "%showsFolder%\!folder!" 
) 

• set "file=%%~nF" получить имя файла, например: set "file=The.Hustle.SXXX.XXX"
• !file:*.S=! является частью после первого».S «например XXX.XXX, так
• set "folder=!file:.S%%~A=!" это имя файла без» .SXXX.XXX», например:„The.Hustle“