Как исправить ошибку времени выполнения в VBA For Loop

Question

Я выполняю следующий код, но получаю ошибка - ошибка выполнения - 6 overlfow.

Швы, такие как rowcount, получают идеальное значение, я могу видеть, когда я перехожу в режим отладки. Но после этого ничего не происходит.

может решить, пожалуйста, для меня?

Private Sub CommandButton1_Click() 
     Dim i As Integer 
     Dim RowCount As Long 

     RowCount = Cells(Rows.Count, "A").End(xlUp).Row 

     For i = RowCount To 2 Step -1 
      If Cells(i, 4) = "7" Then 
       Rows(i).Delete Shift:=xlUp 
      End If 
     Next i 
    End Sub 

Answer 1

Первое, что я хотел бы попробовать:

Dim I as Long 

Answer 2

Хотя комментарий и ответ указывает проблему является вопросом типа данных как технически правильно, есть много лучший способ обработки этого, особенно, если вы перебираете диапазон с таким количеством строк.

Вместо того, чтобы зацикливать, просто отфильтруйте весь диапазон и удалите все строки, соответствующие вашим критериям.

Следующий код автофильтров Sheet1, находя любые ячейки в столбце D, равные 7. Он удаляет эти строки, а затем отключает автофильтр, оставляя нужные строки. Обратите внимание, что с помощью метода смещения вы не будете удалять строку 1, если она имеет в ней 7 или нет.

Добавьте этот код в модуль, и вызовите модуль из вашей кнопки-клик:

Sub DeleteRowsThatMatch() 
    Dim ws As Worksheet 
    Dim rng As Range 
    Dim lastRow As Long 
    Dim match As String 

    Set ws = ThisWorkbook.Sheets("Sheet1") 

    lastRow = ws.Range("D" & ws.Rows.Count).End(xlUp).Row 
    match = "7" 

    Set rng = ws.Range("D1:D" & lastRow) 

    ' filter and delete all but header row 
    With rng 
     .AutoFilter field:=1, Criteria1:="=" & match 
     .Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete 
    End With 

    ' turn off the filters 
    ws.AutoFilterMode = False 
End Sub