Снимите отметку с всех флажков по всей книге через CommandButton

Question

Я хотел бы иметь код, который деактивирует все флажки с именем «CheckBox1» для всех листов в книге. Мой текущий код, к сожалению, не работает, и я не уверен, почему он работает только для активного листа.

Private Sub CommandButton1_Click() 

    Dim Sheet As Worksheet 
    For Each Sheet In ThisWorkbook.Worksheets 

     Select Case CheckBox1.Value 
     Case True: CheckBox1.Value = False 
     End Select 
    Next 
End Sub 

Answer 1

Этого код перебирает через все листы (кроме листов названных Sheet100 и OtherSheet) и неустановленных всех ваших ActiveX флажков с именем CheckBox1

Sub uncheck_boxes() 

    Dim ws As Worksheet 
    Dim xbox As OLEObject 
    For Each ws In ThisWorkbook.Worksheets 
     If ws.Name <> "Sheet100" And ws.Name <> "OtherSheet" Then 
      For Each xbox In ws.OLEObjects 
       ws.OLEObjects("CheckBox1").Object.Value = False 
      Next 
     End If 
    Next 
End Sub 

Чтобы снять все ActiveX флажков во всех листах, не считая имен нас ред

Sub uncheck_all_ActiveX_checkboxes() 

    Dim ws As Worksheet 
    Dim xbox As OLEObject 
    For Each ws In ThisWorkbook.Worksheets 
     For Each xbox In ws.OLEObjects 
      ws.OLEObjects(xbox.Name).Object.Value = False 
     Next 
    Next 
End Sub 

Чтобы снять все Form Control checkboxes на таблицу использовать

Sub uncheck_forms_checkboxes() 

    Dim ws As Worksheet 
    Dim xshape As Shape 
    For Each ws In ThisWorkbook.Worksheets 
     For Each xshape In ws.Shapes 
      If xshape.Type = msoFormControl Then 
       xshape.ControlFormat.Value = False 
      End If 
     Next 
    Next 
End Sub 

Answer 2

[отредактированные следующие комментарии]

Попробуйте это:

Sub test() 
Dim ws As Excel.Worksheet 
Dim s As Object 

For Each ws In ThisWorkbook.Worksheets 
    If ws.Name <> "Definitions" And ws.Name <> "fx" Then 
     Set s = Nothing 
     On Error Resume Next 
     Set s = ws.OLEObjects("CheckBox1") 
     On Error GoTo 0 
     If Not s Is Nothing Then 
      s.Object.Value = False 
     End If 
    End If 
Next ws 

End Sub 

Это глобальная функция (она не принадлежит к конкретному листу), но вы можете поместить его в CommandButton1_Click() если ты хочешь.

Возможно, вам не понадобится блокировка ошибок, если ваши листы (кроме определений и fx) всегда содержат CheckBox1. Альтернативно удалите этот оператор if.