VBA ReadLine Ошибка при чтении из файла

Question

Я использую Excel 2003 & У меня есть следующий код в моем макросе.

Dim fs, a, retstring 
Set fs = CreateObject("scripting.filesystemobject") 
Set a = fs.OpenTextFile("C:\file.txt", ForReading, False) 
Do While a.AtEndofStream <> True 
    retstring = a.ReadLine 
Loop 
a.Close 

Когда я выполняю это, он показывает

"Runtime Error:5"

Invalid Procedure Call or argument at OpenTextFile

Answer 1

Он работал, когда я сделал так.

Dim fs, a, retstring 
    Set fs = CreateObject("scripting.filesystemobject") 
    Set a = fs.OpenTextFile("C:\Users\228319\Desktop\file.txt", 1, False) 
    Do While a.AtEndofStream <> True 
    retstring = a.readline 
    Loop 
    a.Close 

Answer 2

Сначала необходимо определить константу ForReading. И вы можете также определить константы ForWriting и ForAppending, пока вы на нем.

Dim fs, a, retstring 
Const ForReading = 1, ForWriting = 2, ForAppending = 8 
Set fs = CreateObject("Scripting.FileSystemObject") 
Set a = fs.OpenTextFile("C:\file.txt", ForReading, False) 

Do While a.AtEndofStream <> True 
    retstring = a.readline 
Loop 
a.close 

Answer 3

fso считается медленным. Вот более быстрый способ для чтения текстового файла.

Sub Sample() 
    Dim MyData As String, strData() As String 
    Dim i as Long 

    '~~> Read the entire file in 1 go 
    Open "C:\MyFile.Txt" For Binary As #1 
    MyData = Space$(LOF(1)) 
    Get #1, , MyData 
    Close #1 
    strData() = Split(MyData, vbCrLf) 

    For i = LBound(strData) To UBound(strData) 
     Debug.Print strData(i) 
    Next 
End Sub 

Answer 4

Я использую Excel 2007 и получил ту же проблему с близким к тому же фрагменту кода. Включение «Microsoft Scripting Runtime» должно решить его (Главное меню> Инструменты> Ссылки), это сработало для меня.