Как вы разделите строку на основе некоторого разделителя?Имеет ли xslt функцию split()?
Учитывая строку Topic1,Topic2,Topic3
, я хочу, чтобы разделить строку, основываясь на ,
для генерации:
Topic1 Topic2 Topic3
Как вы разделите строку на основе некоторого разделителя?Имеет ли xslt функцию split()?
Учитывая строку Topic1,Topic2,Topic3
, я хочу, чтобы разделить строку, основываясь на ,
для генерации:
Topic1 Topic2 Topic3
В XSLT 1.0 вам необходимо создать рекурсивный шаблон. Эта таблица стилей:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="text/text()" name="tokenize">
<xsl:param name="text" select="."/>
<xsl:param name="separator" select="','"/>
<xsl:choose>
<xsl:when test="not(contains($text, $separator))">
<item>
<xsl:value-of select="normalize-space($text)"/>
</item>
</xsl:when>
<xsl:otherwise>
<item>
<xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
</item>
<xsl:call-template name="tokenize">
<xsl:with-param name="text" select="substring-after($text, $separator)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
Вход:
<root>
<text>Item1, Item2, Item3</text>
</root>
Выход:
<root>
<text>
<item>Item1</item>
<item>Item2</item>
<item>Item3</item>
</text>
</root>
В XSLT 2.0 вы имеете функцию tokenize()
ядра. Таким образом, эта таблица стилей:
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="text/text()" name="tokenize">
<xsl:param name="separator" select="','"/>
<xsl:for-each select="tokenize(.,$separator)">
<item>
<xsl:value-of select="normalize-space(.)"/>
</item>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
Результат:
<root>
<text>
<item>Item1</item>
<item>Item2</item>
<item>Item3</item>
</text>
</root>
Там нет split
функции, но вы можете использовать рекурсивный шаблон с substring-before
и substring-after
, чтобы написать свой собственные.
См. this артикул для деталей.
Спасибо user357812. Я использую свой хороший шаблон с небольшой настройкой, чтобы сделать его родовым:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!-- Main template -->
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()" mode="tokenize-children" />
</xsl:copy>
</xsl:template>
<!-- Split child nodes -->
<xsl:template match="*" mode="tokenize-children">
<xsl:copy>
<xsl:apply-templates select="@*" />
<xsl:apply-templates select="*" mode="tokenize" />
</xsl:copy>
</xsl:template>
<!-- Tokenize text node of child nodes -->
<xsl:template match="*/text()" name="tokenize" mode="tokenize">
<xsl:param name="text" select="."/>
<xsl:param name="separator" select="','"/>
<xsl:variable name="item" select="name(..)" />
<xsl:choose>
<xsl:when test="not(contains($text, $separator))">
<xsl:element name="{$item}">
<xsl:value-of select="normalize-space($text)"/>
</xsl:element>
</xsl:when>
<xsl:otherwise>
<xsl:element name="{$item}">
<xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
</xsl:element>
<xsl:call-template name="tokenize">
<xsl:with-param name="text" select="substring-after($text, $separator)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
В зависимости от того, что XSL процессор вы используете, вы можете иметь доступ к функции расширения str:tokenize().
Таким образом, чтобы разделить Topic1,Topic2,Topic3
на ,
do;
<xsl:copy-of select="str:tokenize('Topic1,Topic2,Topic3', ',')"/>
которое даст результат;
<token>Topic1</token>
<token>Topic2</token>
<token>Topic3</token>
XSLT 1.0
мне нужен легкий вариант по сравнению с другими ответами здесь.
Входной сигнал:
1, 2, 3
Ouput:
1, 2 и 3
Вход:
Выход
Если разделитель пространства вместо запятой, он будет работать.
Входной сигнал:
Ouput:
1, 2 и 3
Я только что создал слегка измененный шаблон.
<xsl:template name="tokenizeString">
<xsl:param name="list"/>
<xsl:param name="delimiter"/>
<xsl:choose>
<xsl:when test="contains($list, $delimiter)">
<xsl:variable name="listLength" select="string-length($list)" />
<xsl:variable name="listLengthWithoutDelimiters" select="string-length(translate($list, $delimiter,''))" />
<xsl:variable name="noOfDelimiters" select="($listLength - $listLengthWithoutDelimiters)" />
<xsl:value-of select="substring-before($list,$delimiter)"/>
<xsl:if test="$noOfDelimiters > 1">, </xsl:if>
<xsl:if test="$noOfDelimiters = 1"> and </xsl:if>
<xsl:call-template name="tokenizeString">
<xsl:with-param name="list" select="substring-after($list,$delimiter)"/>
<xsl:with-param name="delimiter" select="$delimiter"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:choose>
<xsl:when test="$list = ''">
<xsl:text/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$list"/>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
Шаблон может быть названа, как показано ниже, когда разделитель запятой
<xsl:call-template name="tokenizeString">
<xsl:with-param name="list">1, 2, 3</xsl:with-param>
<xsl:with-param name="delimiter">
<xsl:value-of select="','" />
</xsl:with-param>
</xsl:call-template>
Шаблон может быть названа, как показано ниже, когда разделитель пространства
<xsl:call-template name="tokenizeString">
<xsl:with-param name="list">1 2 3</xsl:with-param>
<xsl:with-param name="delimiter">
<xsl:value-of select="' '" />
</xsl:with-param>
</xsl:call-template>
возможно duplicate of [Есть ли у XSLT функция Split()?] (http://stackoverflow.com/questions/136500/does-xslt-have-a-split-function) –