malformed JSON string в Perl

Question

Я пытаюсь преобразовать json-файл в xml. Таким образом, сканируется каталог JSON, и если любой файл, который прибывает туда, будет преобразован в xml и перенесен в каталог xml.

Но я получаю эту ошибку

Readline() на закрытом файловом дескрипторе $ ФХ на json.pl линии 29.
искаженной строка JSON, ни массив, объект, число, строка или атом, по характеру смещение 0 (перед тем "(конец строки)") на линии json.pl 34

json.pl

#!/usr/bin/perl 

use strict; 
use warnings; 
use File::Copy; 

binmode STDOUT, ":utf8"; 
use utf8; 

use JSON; 
use XML::Simple; 

# Define input and output directories 
my $indir = 'json'; 
my $outdir = 'xml'; 

# Read input directory 
opendir DIR, $indir or die "Failed to open $indir"; 
my @files = readdir(DIR); 
closedir DIR; 

# Read input file in json format 
for my $file (@files) 
{ 
my $json; 
{ 
    local $/; #Enable 'slurp' mode 
    open my $fh, "<", "$indir/$file"; 
    $json = <$fh>; 
    close $fh; 
} 

# Convert JSON format to perl structures 
my $data = decode_json($json); 

# Output as XML 
open OUTPUT, '>', "$outdir/$file" or die "Can't create filehandle: $!"; 
select OUTPUT; $| = 1; 
print "<?xml version=\"1.0\" encoding=\"UTF-8\" standalone=\"yes\"?>\n"; 
print XMLout($data); 
print "\n" ; 
close(OUTPUT); 
unlink "$indir/$file"; 

} 

example.js на

{ 
"Manager": 
    { 
     "Name" : "Mike", 
     "Age": 28, 
     "Hobbies": ["Music"] 
    }, 
"employees": 
    [ 
     { 
      "Name" : "Helen", 
      "Age": 26, 
      "Hobbies": ["Movies", "Tennis"] 
      }, 
     { 
      "Name" : "Rich", 
      "Age": 31, 
      "Hobbies": ["Football"] 

     } 
    ] 
} 

Answer 1

Вы не проверять на наличие ошибок во время open, и вы не пропуская записи каталога (readdir вернет . и .. записи).

Если вы используете

open my $fh, "<", "$indir/$file" or die "$file: $!"; 

вы, вероятно, найти проблему быстро.

"readline() на закрытом дескрипторе файла $ fh" говорит "open $fh не удалось, но вы все равно продолжали идти".

Answer 2

Как указал @cjm, проблема в том, что вы пытаетесь открыть и прочитать каталоги, а также файлы из исходного каталога.

Это исправление для этого, и оно также использует autodie, чтобы избежать постоянной проверки состояния всех операций ввода-вывода. Я тоже немного прибрал вещи.

#!/usr/bin/perl 

use utf8; 
use strict; 
use warnings; 
use autodie; 

use open qw/ :std :encoding(utf8) /; 

use JSON qw/ decode_json /; 
use XML::Simple qw/ XMLout /; 

my ($indir, $outdir) = qw/ json xml /; 

my @indir = do { 
    opendir my $dh, $indir; 
    readdir $dh; 
}; 

for my $file (@indir) { 

    my $infile = "$indir/$file"; 
    next unless -f $infile; 

    my $json = do { 
    open my $fh, '<', $infile; 
    local $/; 
    <$fh>; 
    }; 

    my $data = decode_json($json); 

    my $outfile = "$outdir/$file"; 
    open my $out_fh, '>', "$outdir/$file"; 
    print $out_fh '<?xml version="1.0" encoding="UTF-8" standalone="yes"?>', "\n"; 
    print $out_fh XMLout($data), "\n"; 
    close $out_fh; 

    unlink $infile; 
}