SPARQL рассчитывать не существующие свойства, как нулевой

Question

Вот мой запрос:

PREFIX  : <http://example.org/ns#> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
SELECT ?id ?name (count(?s) as ?count) 
WHERE { 
    ?t a  :Tag ; 
     :hasId ?id ; 
     :hasName ?name 
    OPTIONAL { ?s :hasTag ?t ; 
       rdf:type ?type } 
    FILTER (?type in (:Client, :Project, :Staff)) 
} GROUP BY ?id ?name 

Теги без каких-либо объектов, которые не включены в результат. Как я могу получить их, не используя союз? Эффективность также важна.

Целью является сбор информации о тегах (id, name) и количестве объектов, которые они назначают (если таких объектов не должно быть 0). Пример данных тегов:

:tag912 :hasId  "912"^^xsd:integer 
:tag912 :hasName  "Phones" 

Этот тег относится к 6 объектам.

Этот запрос работает для меня:

PREFIX :  <http://example.org/ns#> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
SELECT ?id ?name ?count 
WHERE { 
    { 
    SELECT ?id ?name (count(?s) as ?count) 
    WHERE { 
     ?t a  :Tag ; 
      :hasId ?id ; 
      :hasName ?name . 
     ?s :hasTag ?t ; 
      rdf:type ?type 
     FILTER (?type in (:Client, :Project, :Staff)) 
    } GROUP BY ?id ?name 
    } UNION { 
    SELECT ?id ?name (0 as ?count) 
    WHERE { 
     ?t a  :Tag ; 
     :hasId ?id ; 
     :hasName ?name 
     FILTER not exists { ?s :hasTag ?t } 
    } 
    } 
} 

Как я могу использовать привязок здесь? Улучшит ли производительность? Спасибо

Answer 1

Почему не использование UNION?

Помимо этого, ваш запрос ориентирован на ?t тегов и их ?id и ?name - так что это не удивительно, что результаты не включают ?s объекты, которые испытывают недостаток в ?t и, следовательно, не хватает какой-либо ?id и ?name ...

Я думаю, это может заставить вас идти в правильном направлении -

PREFIX  : <http://example.org/ns#> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 

SELECT ?id 
     ?name 
     (count(?s) as ?count) 
WHERE 
    {   ?s rdf:type ?type 
       FILTER (?type IN (:Client, :Project, :Staff)) . 
    OPTIONAL { ?s :hasTag ?t . 
       ?t rdf:type :Tag ; 
        :hasId ?id ; 
        :hasName ?name } 
    } 
GROUP BY ?id ?name 

Answer 2

вы можете проверить, если s связан в фильтре:

PREFIX  : <http://example.org/ns#> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
SELECT ?id ?name (COUNT(?s) as ?count) 
WHERE { 
    ?t a  :Tag ; 
     :hasId ?id ; 
     :hasName ?name . 
    OPTIONAL { 
    ?s :hasTag ?t ; 
      rdf:type ?type . 
    } 
    FILTER (!BOUND(?s) || ?type in (:Client, :Project, :Staff)) 
} GROUP BY ?id ?name 

Однако я не знаю, было ли это быстрее, чем объединение (или объединение союзов).