Почему это вызывает несоответствие типа?

Question

У меня есть приложение VB6, которое вызывает отчет Crystal Report XI. Однако, когда я пытаюсь изменить информацию о подключении, я получаю несоответствие типа. Любая помощь будет оценена по достоинству.

Dim Report As craxddrt.Report ' This is how Report is defined 

ChangeReportTblLocation Report ' This is the function where the mismatch occurs 

Это определение ChangeReportTblLocation:

Private Function ChangeReportTblLocation(ByRef pReport As craxddrt.Report) As Boolean 

    Dim ConnectionInfo As craxddrt.ConnectionProperties 
    Dim crxTables  As craxddrt.DatabaseTables 
    Dim crxTable  As craxddrt.DatabaseTable 
    Dim crxSections  As craxddrt.Sections 
    Dim crxSection  As craxddrt.section 
    Dim crxSubreportObj As craxddrt.SubreportObject 
    Dim crxReportObjects As craxddrt.ReportObjects 
    Dim crxSubreport As craxddrt.Report 
    Dim ReportObject As Object 
    Dim Y    As Integer 
    Dim lsDatabase  As String 

    On Error GoTo errHandle_CRTL 


    lsDatabase = GetCurrentUserRoot("SOFTWARE\COTTSYSTEMS\APP", "Database") 

    If lsDatabase = "" Then 
     lsDatabase = gConn.DefaultDatabase 
    End If 

    If lsDatabase = "" Then 
     lsDatabase = "frasys" 
    End If 

    With pReport 

     For Y = 1 To .Database.Tables.Count 
      Set ConnectionInfo = .Database.Tables(Y).ConnectionProperties 

      ConnectionInfo.DeleteAll 
      ConnectionInfo.Add "DSN", frasysdsn 
      ConnectionInfo.Add "Database", lsDatabase 

      'This is the Line that causes the type mismatch 
      .Database.Tables(Y).Location = lsDatabase & ".dbo." & Database.Tables(Y).Location 

     Next Y 

     Set crxSections = .Sections 

     For Each crxSection In crxSections 

      Set crxReportObjects = crxSection.ReportObjects 

      For Each ReportObject In crxReportObjects 

       If ReportObject.Kind = crSubreportObject Then 
        Set crxSubreportObj = ReportObject 
        Set crxSubreport = crxSubreportObj.OpenSubreport 
        Set crxTables = crxSubreport.Database.Tables 

        For Y = 1 To crxTables.Count 
         Set crxTable = crxTables.Item(Y) 
         crxTable.Location = lsDatabase & ".dbo." & crxTable.Location 

        Next Y 

       End If 
      Next ReportObject 
     Next crxSection 

    End With 

    Set ConnectionInfo = Nothing 
    Set crxTables = Nothing 
    Set crxTable = Nothing 
    Set crxSections = Nothing 
    Set crxSection = Nothing 
    Set crxSubreportObj = Nothing 
    Set crxReportObjects = Nothing 
    Set crxSubreport = Nothing 
    Set ReportObject = Nothing 

    ChangeReportTblLocation = True 

    Exit Function 
errHandle_CRTL: 
    Screen.MousePointer = vbDefault 
    MsgBox err.Number, err.Description, "ChangeReportTblLocation", err.Source 
End Function 

Answer 1

Я думаю, что его просто опечатка:

.Database.Tables(Y).Location = lsDatabase & ".dbo." & .Database.Tables(Y).Location 

Я добавил . перед второй Database.Tables(Y).Location в этом l ине.

Это означает, что вы не используете Option Explicit в своем коде. Я не могу достаточно подчеркнуть, насколько важно использовать это. Это сэкономит вам много времени на поиск нечетных опечаток (например, это) и сохранит ваш код от всех видов странных вещей.

Answer 2

попробуйте использовать call ChangeReportTblLocation(Report)