Объединение пулов Perl

Question

Прямо сейчас у нас есть большое приложение perl, использующее необработанный DBI для подключения к MySQL и выполнения SQL-операторов. Он создает соединение каждый раз и заканчивается. Начали приближаться к пределу соединения mysql (200 раз)

Похоже, что DBIx::Connection поддерживает объединение пулов прикладного уровня.

Есть ли у кого-нибудь опыт работы с DBIx::Connection?. Есть ли другие соображения для объединения пулов?

Я также вижу mod_dbd, который является модемом Apache, который выглядит так, как будто он связан с пулом соединений. http://httpd.apache.org/docs/2.1/mod/mod_dbd.html

Answer 1

У меня нет никакого опыта работы с DBIx :: Connection, но я использую DBIx::Connector (по существу, что использует внутренне DBIx :: Class, но встраиваемый) и это замечательно ...

Я объединить эти соединения с Мусом объекта оберткой, что руки назад существующие экземпляры объектов, если параметры соединения идентичны (это будет работать то же самое для любого исходного объекта БД):

package MyApp::Factory::DatabaseConnection; 
use strict; 
use warnings; 

use Moose; 

# table of database name -> connection objects 
has connection_pool => (
    is => 'ro', isa => 'HashRef[DBIx::Connector]', 
    traits => ['Hash'], 
    handles => { 
     has_pooled_connection => 'exists', 
     get_pooled_connection => 'get', 
     save_pooled_connection => 'set', 
    }, 
    default => sub { {} }, 
); 

sub get_connection 
{ 
    my ($self, %options) = @_; 

    # some application-specific parsing of %options here... 

    my $obj; 
    if ($options{reuse}) 
    { 
     # extract the last-allocated connection for this database and pass it 
     # back, if there is one. 
     $obj = $self->get_pooled_connection($options{database}); 
    } 

    if (not $obj or not $obj->connected) 
    { 
     # look up connection info based on requested database name 
     my ($dsn, $username, $password) = $self->get_connection_info($options{database}); 
     $obj = DBIx::Connector->new($dsn, $username, $password); 

     return unless $obj; 

     # Save this connection for later reuse, possibly replacing an earlier 
     # saved connection (this latest one has the highest chance of being in 
     # the same pid as a subsequent request). 
     $self->save_pooled_connection($options{database}, $obj) unless $options{nosave}; 
    } 

    return $obj; 
} 

Answer 2

Только убедившись, что вы знаете о DBI->connect_cached(), верно? Это замена для connect(), которая повторяет использование dbh, когда это возможно, в течение срока действия вашего скрипта perl. Возможно, ваша проблема разрешима, добавив 7 символов :)

И соединения MySQL относительно дешевы. Работа с вашей БД на max_connections=1000 или больше сама по себе не вызовет проблем. (Если ваши клиенты требуют больше работы, чем может обрабатывать ваша БД, это более серьезная проблема, одна из которых ниже max_connections может отложить, но, конечно, не решить.)