Импорт ежедневного файла с именем переменной в базу данных доступа

Question

Позвольте мне извиниться заранее, если этот вопрос задан где-то, и я его не заметил. Я потратил несколько дней на это и не могу заставить его работать на 100%.

Я пытаюсь импортировать файл Excel, который отправляется по электронной почте каждое утро в базу данных доступа. В файле есть дата, которая меняется каждый день. Именование происходит по той же схеме каждый день «FTTQ m-dd-yyyy». День, указанный в имени файла, относится к предыдущему рабочему дню, например. получать по электронной почте 8/25 для FTTQ 8/24. Код ниже - это то, что у меня есть до сих пор, и оно будет проходить через папку, однако, когда он достигнет правильного дня, он не сможет его найти. Я пробовал пару вариантов, но Access продолжает сбой, когда я пытаюсь запустить его. В идеале мне нужен доступ, чтобы найти последнюю дату в файле и импортировать его, например, приходить в понедельник и получать файл за пятницу/субботу или в течение недели, получая его за день до этого. Любая помощь будет оценена.

Private Sub Button1_Click() 
Dim strToday As String 
Dim strFilePath as String 
Dim strFile as String 

strToday = Format(Date, "m-dd-yyyy") 
strFilePath = "C:\Users\cole.stratton\Documents\Procurement\FTTQ 'Note:FTTQ is the beginning of the file name 
strFile = Dir(strFilePath, "*.xlsx") 

    Do While strFile <> "" 
    If Right(strFile,14) = strToday & ".xlsx" Then 
     DoCmd.TransferSpreadsheet, acImport, "tblTest",strFile, True 
    End If 
    strFile = Dir 'Note: I do not understand the point of this line or what it does or supposed to do. 
    Loop 
End Sub 

Answer 1

Чтобы найти последнюю существующий файл, я хотел бы изменить цикл так:

Dim searchDate As Date 
Dim strDate As String 
Dim strFilePath As String 
Dim strFile As String 
Dim i As Long 

' Search backwards from today for a file with the date name 
For i = 0 To -7 Step -1 
    searchDate = DateAdd("d", i, Date) 
    strDate = Format(searchDate, "m-dd-yyyy") 
    strFilePath = "C:\Users\cole.stratton\Documents\Procurement\FTTQ " & strDate & ".xlsx" 
    Debug.Print "Looking for: " & strFilePath 
    ' Check if file exists 
    strFile = Dir(strFilePath) 
    If strFile <> "" Then 
     ' Note that Dir() only returns the file name, so use strFilePath 
     DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel12, "tblTest", strFilePath, True 
     ' file found, exit loop 
     Exit For 
    End If 
Next i 

Answer 2

*** Я предполагаю, что у вас есть закрытие "в вашей strFilePath линии в реальном коде. ****

Эта линия выглядит вопрос ...

strFile = Dir(strFilePath, "*.xlsx")

Эта страница покажет вам правильный синтаксис для использования Dir ... http://www.techonthenet.com/excel/formulas/dir.php

strFile = Dir(strFilePath & "*.xlsx") < - вы помещали расширение файла туда, куда должны были идти атрибуты.

Однако вам также необходимо изменить дату. Если файл будет иметь вчерашнюю дату, а не сегодняшние ... strToday = Format(Date-1, "m-dd-yyyy")

Эту линия ... strFile = Dir

устанавливает вашу строку к следующему имени файла, которое соответствует вашим критериям поиска.