Запрос WMI для получения списка пакетов обновления

Question

Возможно ли узнать пакеты обновления, установленные на компьютере под управлением Windows 2000 с использованием WMI?

Answer 1

Там в предложенном способе получения установленного программного обеспечения с помощью WMI - хотя и не все программное обеспечение показывает вверх, так что вы должны были бы ...

1) Попробуйте его и посмотреть, если они появятся на всех

2) Отрегулируйте пример для фильтрации результатов, так только пакеты услуг показать

strHost = "." 
Const HKLM = &H80000002 
Set objReg = GetObject("winmgmts://" & strHost & _ 
    "/root/default:StdRegProv") 
Const strBaseKey = _ 
    "Software\Microsoft\Windows\CurrentVersion\Uninstall\" 
objReg.EnumKey HKLM, strBaseKey, arrSubKeys 
For Each strSubKey In arrSubKeys 
    intRet = objReg.GetStringValue(HKLM, strBaseKey & strSubKey, _ 
     "DisplayName", strValue) 
    If intRet <> 0 Then 
     intRet = objReg.GetStringValue(HKLM, strBaseKey & strSubKey, _ 
     "QuietDisplayName", strValue) 
    End If 
    If (strValue <> "") and (intRet = 0) Then 
     WScript.Echo strValue 
    End If 
Next 

Answer 2

Да, класс WMI Win32_OperatingSystem содержит всю эту информацию. Я могу видеть, проверить эту информацию с помощью PowerShell, чтобы проверить свою локальную машину:

PS c:\> get-wmiobject win32_operatingsystem | ` 
      select BuildNumber, ServicePackMajorVersion, ` 
      ServicePackMinorVersion | format-table -auto 

BuildNumber ServicePackMajorVersion ServicePackMinorVersion 
----------- ----------------------- ----------------------- 
7100        0      0 

Примечание: Powershell работает только на XP или выше, но вы можете проверить удаленные системы, передавая -Компьютер параметр, чтобы получить-WmiObject.

Answer 3

VBScript пример из серии: Hey, Scripting Guy!

strComputer = "." 
Set objWMIService = GetObject("winmgmts:" _ 
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 

Set colOperatingSystems = objWMIService.ExecQuery _ 
    ("Select * from Win32_OperatingSystem") 

For Each objOperatingSystem in colOperatingSystems 
    Wscript.Echo objOperatingSystem.ServicePackMajorVersion _ 
     & "." & objOperatingSystem.ServicePackMinorVersion 
Next