Pass VBA Variable to Access Query (Excel VBA)

Question

Im new при попытке построить запросы из vba. Я пытаюсь понять, как передать переменную внутри синтаксиса VBA. Помнишь, где я немой?

Я пробовал это ниже, но появляется ошибка автоматизации, которая появляется. Ive заметил от игры aroudn, что ошибки автоматизации возникают, когда вы просто получили синтаксис неправильно, так что, надеюсь, что-то маленькое?

Любая помощь очень ценится

Sub GetDataFromAccess() 
    Dim cmd As New ADODB.Command, rs As ADODB.Recordset 
    Dim recordNum As Integer 

    recordNum = 7 

    cmd.ActiveConnection = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=C:\Users\Ashleysaurus\Desktop" & "\" & "xyzmanu3.accdb" 
    cmd.CommandType = adCmdText 

    cmd.CommandText = "SELECT * FROM Invoice WHERE OrderNumber <" & "'" & recordNum & "'" & "ORDER BY OrderNumber ASC" 

    Set rs = cmd.Execute 
    Sheet1.Range("A2").CopyFromRecordset rs 

    rs.Close 
    cmd.ActiveConnection.Close 

    Debug.Print "Done!" 
End Sub 

Answer 1

Предполагая ORDERNUMBER это число, не используйте кавычки. Также убедитесь, что у вас есть пространство перед заказом By:

cmd.CommandText = "SELECT * FROM Invoice WHERE OrderNumber <" & recordNum & " ORDER BY OrderNumber ASC" 

Answer 2

В процессе обучения для построения VBA запросов, рассмотрим параметризованные запросы и избежать необходимости цитат! Это лучшая практика в отрасли на всех языках при передаче значений в динамических SQL-запросах.

Sub GetDataFromAccess() 
    Dim cmd As New ADODB.Command, rs As ADODB.Recordset 
    Dim recordNum As Integer 

    recordNum = 7 

    With cmd 
     .ActiveConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" _ 
       & "Data Source=C:\Users\Ashleysaurus\Desktop" & "\" & "xyzmanu3.accdb" 
     .CommandType = adCmdText 
     .CommandText = "SELECT * FROM Invoice" _ 
         & " WHERE OrderNumber < ? ORDER BY OrderNumber ASC"  
    End With 

    cmd.Parameters.Append cmd.CreateParameter("recordNumParam", adInteger, adParamInput, 10) 
    cmd.Parameters(0).Value = recordNum 

    Set rs = cmd.Execute 
    Sheet1.Range("A2").CopyFromRecordset rs 

    rs.Close 
    cmd.ActiveConnection.Close 

    Debug.Print "Done!" 

End Sub