Редактировать или экспортировать выпадающие списки в Excel

Question

Работа с существующей таблицей, содержащей два раскрывающихся списка. Возможно ли экспортировать или отредактировать данные из этих списков?

Answer 1

В списке проверки данных вы можете использовать эти 3 сценария.

А) Формула, которая относится к диапазону в том же листе

Б) список, который непосредственно вводятся с запятыми

C) Формула, которая относится к именованному диапазону от s AME/другой лист

Теперь нам нужно, чтобы удовлетворить всех трех сценариев в случае, если мы хотим получить этот список.

Чтобы получить доступ к списку ячейки проверки достоверности данных, вы должны использовать Rng.Validation.Formula1

Посмотреть этот код.

Sub Sample() 
    Dim ws As Worksheet 
    Dim dvRng As Range, rng As Range 
    Dim strList As String 
    Dim MyAr() As String 

    Set ws = ThisWorkbook.Sheets("Sheet1") 
    Set dvRng = ws.Range("A1") ' Case A 
    'Set dvRng = ws.Range("C1") ' Case B 
    'Set dvRng = ws.Range("E1") ' Case C 

    '~~> Get the formula in the data validation 
    strList = dvRng.Validation.Formula1 

    '~~> Check if it has an = sign for Case A and Case C 
    If InStr(1, strList, "=") Then 
     strList = Replace(strList, "=", "") 
     Set rng = Range(strList) 
     rng.Copy Sheet2.Range("A1") 
    Else 
    '~~> Case B 
     If InStr(1, strList, ",") Then 
      MyAr = Split(strList, ",") 
      Sheet2.Range("A1:A" & UBound(MyAr) + 1).Resize.Value = Application.Transpose(MyAr) 
     Else 
      Sheet2.Range("A1").Value = strList 
     End If 
    End If 
End Sub 

Я прокомментировал код, чтобы вы не столкнулись с какими-либо проблемами. Тем не менее, если вы это сделаете, просто спросите:

Answer 2

Если кто-то не имеет лучшего представления, я выбрал каждый из элементов в другую ячейку, а затем скопировал это в файл csv, где я могу импортировать его в таблицу.