ActionScript 3 - добавление градиента к объекту

Question

У меня есть экземпляр MovieClip под названием «BlueBox», который представляет собой только «Drawing Object», который является синим. Он находится внутри контейнера под названием «option1MC», который находится внутри «option1Container», который находится на стадии .. Это цвет может быть изменен следующим образом:

option1Container.addEventListener(MouseEvent.MOUSE_OVER, option1ContainerOver); 

var optionOver:ColorTransform = new ColorTransform(); 
optionOver.color = 0xC56516; 

function option1ContainerOver(evt:Event):void { 
    option1Container.option1MC.BlueBox.transform.colorTransform = optionOver; 
} 

Я хочу изменить цвет градиента. Это то, что я пробовал:

var mtr:Matrix = new Matrix(); 
mtr.createGradientBox(option1Container.option1MC.BlueBox.width, option1Container.option1MC.BlueBox.height, 0, 0, 0); 
mtr.graphics.beginGradientFill(GradientType.LINEAR, [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], mtr); 
mtr.graphics.drawRect(0,0,option1Container.option1MC.BlueBox.width, option1Container.option1MC.BlueBox.height); 

Однако сейчас, когда я запускаю файл .fla, это я дает мне ошибку говоря:

Access of possible undefined property graphics through a reference with static type flasg.geom:Matrix: 

и имеет в виду линий

mtr.graphics.beginGradientFill(GradientType.LINEAR, [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], mtr); 
mtr.graphics.drawRect(0,0,option1Container.option1MC.BlueBox.width, option1Container.option1MC.BlueBox.height); 

Любая идея, почему?

Answer 1

A Matrix не имеет graphics. Вам нужно будет применить это к DisplayObject с имуществом graphics. Это будет выглядеть примерно так с вашей установкой:

//create the sprite to do the gradient fill on or use your MovieClip 
//var spriteObject:Sprite = new Sprite() or just use option1Container; 

//enter your matrix 
var mtr:Matrix = new Matrix(); 
mtr.createGradientBox(option1Container.BlueBox.width, option1Container.BlueBox.height, 0, 0, 0); 

//apply it to the sprite 
sprite.graphics.beginGradientFill("linear", [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], mtr); 
sprite.graphics.drawRect(0, 0, 50, 40); 
sprite.graphics.endFill(); 
addChild(sprite); 

Я создал переменные спрайты здесь, что не нужно, как вы можете просто поменять sprite с option1Container

Вы можете ссылаться на помощи компании Adobe для этого, а также: http://help.adobe.com/en_US/as3/dev/WS5b3ccc516d4fbf351e63e3d118a9b90204-7dd7.html

Теперь, если вы нарисовали графику в IDE, вы в настоящее время не сможете ее изменить. В этом случае вы можете создать новую MovieClip и добавить его в контейнер, как так:

//note I made a target variable just to save on typing: 
var target:MovieClip = option1Container.option1MC.BlueBox; 
var gradientLayer:MovieClip = new MovieClip(); 

var gradientBox:Matrix = new Matrix(); 
gradientBox.createGradientBox(target.width, target.height, 0, 0, 0); 
gradientLayer.graphics.beginGradientFill("linear", [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], gradientBox); 
gradientLayer.graphics.drawRect(0, 0, target.width, target.height); 
gradientLayer.graphics.endFill(); 

//giving the asset a name will allow you to easily remove it later 
gradientLayer.name = "gradientLayer"; 

target.addChild(gradientLayer); 

Примечание Я дал Градиент актива имя «gradientLayer». Если вы хотите удалить этого ребенка позже, вы можете сделать это с помощью:

option1Container.option1MC.BlueBox.removeChild(option1Container.option1MC.BlueBox.getChildByName("gradientLayer"));