просмотра списка переменных карт в переплетении данных сценария

Question

У меня есть список карт (listOfMapsObject), как показано ниже

[ 
{ 
    "Id" : "1234", 
    "Value" : "Text1" 
    }, 
    { 
    "Id" : "1235", 
    "Value" : "Text2" 
    } 
] 

Я хотел бы поле доступа «Value» для данного идентификатора в dataweave сценария. Например: для Id = 1234, Text1 должен быть возвращен.

%dw 1.0 
%output application/json 
%var listOfMapsObject = flowVars.listOfMaps 
--- 
payload map { 
    "key" : $.key, 
    "data" : lookup Value field in listOfMapsObject by given key 
} 

Answer 1

Я создаю свой собственный объект с немного аналогичным объектом и успешно доступом поле «значение» со следующим DataWeave выражения:

%dw 1.0 
%output application/json 
%var listOfMapsObject = flowVars.listOfMaps 
--- 
payload map using(data = $) { 
    "key" : data.key, 
    "data" : (listOfMapsObject filter $.id == data.key).value reduce ($$ ++ $) 
} 

Вы можете изменить его с помощью собственного объекта, например: заменить «id» с «Id». Тест и оценить результат с помощью filter, flatten, reduce и т.д.

Answer 2

Approch предложил @ «sulthony ч» это хорошо, но это будет в конечном итоге в вопросе производительности, если большое количество данных в pyload и listOfMapsObject. Поскольку фильтр используется, для каждой записи сценария полезной нагрузки будет выполняться цикл для всех записей в файле flowVars.listOfMaps.

Следующее будет работать нормально и отображать значение карты только один раз.

%dw 1.0 
%output application/json 
%var dataLookup = {(flowVars.listOfMaps map { 
     ($.Id): $.Value 
    })} 
--- 
payload map { 
    key : $.key, 
    data : dataLookup[$.key] 
} 

output-

[ 
    { 
    "key": "1234", 
    "data": "Text1" 
    }, 
    { 
    "key": "1235", 
    "data": "Text2" 
    } 
] 

Где Payload -

[ 
{ 
    "key" : "1234" 
    }, 
    { 
    "key" : "1235" 
    } 
] 

И -

[ 
{ 
    "Id" : "1234", 
    "Value" : "Text1" 
    }, 
    { 
    "Id" : "1235", 
    "Value" : "Text2" 
    } 
] 

Надеется, что это помогает.