Каков правильный способ вложения исключений? - Использование Delphi

Question

Предположим, у меня есть три (или более) процедуры, некоторые из которых называют друг друга, как показано ниже, любой из которых может выйти из строя.

Если какой-либо из них не работает, я хочу, чтобы «главная» программа немедленно регистрировала сбой и завершала программу.

Каков правильный синтаксис для использования в Delphi для «возврата» исключения к каждому предыдущему вызову процедуры?

Еще лучше, если кто-то может помочь мне получить блок Try/except основной программы, чтобы определить, какой бит не удалось!

Пример псевдокода из трех процедур и основной программы может выглядеть следующим образом.

(я думаю, я понимаю принцип, что-то делать с «рейз», но хотел бы получить некоторую помощь с фактическим синтаксисом и какой код должен я использовать)

////////////////////////////////////// 
Procedure DoProcA 
begin 
try 
    begin 
    {stuff}; //stuff that might fall 
    end; 
except 
on E : Exception do 
    begin 
    LogError ('error in A'); 
    end //on E 
end;//try 

////////////////////////////////////// 

Procedure DoProcB 
begin 
try 
    begin 
    Do ProcC; //another proc that might fail 
    {other stuff} 
    end; 
except 
on E : Exception do 
    begin 
    LogError ('error in B'); 
    end //on E 
end;//try 

////////////////////////////////////// 

Procedure DoProcC 
begin 
try 
    begin 
    {Do stuff} //even more stuf fthat might fail 
    end; 
except 
on E : Exception do 
    begin 
    LogError ('error in C'); 
    end //on E 
end;//try 

////////////////////////////////////// 

//Main programo 
begin 
try 
    DoProcA; 
    DoProcB; 
    {other stuff} 
except 
    {here I want to be able to do something like 
    if failure of A, B or C then 
     begin  
     LogError ('Failure somewhere in A, B or C'); 
     application.terminate; 
     end;} 
end; //try 
end. 

Answer 1

Пусть каждая функция ререйз пойманная исключение после его регистрации, например:

Procedure DoProcA; 
begin 
    try 
    {stuff}; //stuff that might fall 
    except 
    on E : Exception do 
    begin 
     LogError ('error in A'); 
     raise; // <-- here 
    end; 
    end; 
end; 

Procedure DoProcB; 
begin 
    try 
    DoProcC; //another proc that might fail 
    {other stuff} 
    except 
    on E : Exception do 
    begin 
     LogError ('error in B'); 
     raise; // <-- here 
    end; 
    end; 
end; 

Procedure DoProcC; 
begin 
    try 
    {Do stuff} //even more stuff that might fail 
    except 
    on E : Exception do 
    begin 
     LogError ('error in C'); 
     raise; // <-- here 
    end; 
    end; 
end; 

begin 
    try 
    DoProcA; 
    DoProcB; 
    {other stuff} 
    except 
    on E: Exception do 
    begin 
     LogError ('Failure somewhere in A, B or C'); 
     //Application.Terminate; // this is not useful unless Application.Run is called first 
    end; 
    end; 
end. 

Если вы хотите основную процедуру, чтобы определить, какие функции не удалось, вам нужно передать эту информацию по цепочке исключения, например:

type 
    MyException = class(Exception) 
    public 
    WhichFunc: String; 
    constructor CreateWithFunc(const AWhichFunc, AMessage: String); 
    end; 

constructor MyException.CreateWithFunc(const AWhichFunc, AMessage: String); 
begin 
    inherited Create(AMessage); 
    WhichFunc := AWhichFunc; 
end; 

Procedure DoProcA; 
begin 
    try 
    {stuff}; //stuff that might fall 
    except 
    on E : Exception do 
    begin 
     raise MyException.CreateWithFunc('DoProcA', E.Message); // <-- here 
    end; 
    end; 
end; 

Procedure DoProcB; 
begin 
    try 
    DoProcC; //another proc that might fail 
    {other stuff} 
    except 
    on E : MyException do 
    begin 
     raise; // <-- here 
    end; 
    on E : Exception do 
    begin 
     raise MyException.CreateWithFunc('DoProcB', E.Message); // <-- here 
    end; 
    end; 
end; 

Procedure DoProcC; 
begin 
    try 
    {Do stuff} //even more stuff that might fail 
    except 
    on E : Exception do 
    begin 
     raise MyException.CreateWithFunc('DoProcC', E.Message); // <-- here 
    end; 
    end; 
end; 

begin 
    try 
    DoProcA; 
    DoProcB; 
    {other stuff} 
    except 
    on E: MyException do 
    begin 
     LogError ('Failure in ' + E.WhichFunc + ': ' + E.Message); 
    end; 
    on E: Exception do 
    begin 
     LogError ('Failure somewhere else: ' + E.Message); 
    end; 
    end; 
end. 

Или:

type 
    MyException = class(Exception) 
    public 
    WhichFunc: String; 
    constructor CreateWithFunc(const AWhichFunc, AMessage: String); 
    end; 

constructor MyException.CreateWithFunc(const AWhichFunc, AMessage: String); 
begin 
    inherited Create(AMessage); 
    WhichFunc := AWhichFunc; 
end; 

Procedure DoProcA; 
begin 
    try 
    {stuff}; //stuff that might fall 
    except 
    on E : Exception do 
    begin 
     raise MyException.CreateWithFunc('DoProcA', E.Message); // <-- here 
    end; 
    end; 
end; 

Procedure DoProcB; 
begin 
    try 
    DoProcC; //another proc that might fail 
    {other stuff} 
    except 
    on E : Exception do 
    begin 
     Exception.RaiseOuterException(MyException.CreateWithFunc('DoProcB', E.Message)); // <-- here 
    end; 
    end; 
end; 

Procedure DoProcC; 
begin 
    try 
    {Do stuff} //even more stuff that might fail 
    except 
    on E : Exception do 
    begin 
     raise MyException.CreateWithFunc('DoProcC', E.Message); // <-- here 
    end; 
    end; 
end; 

var 
    Ex: Exception; 
begin 
    try 
    DoProcA; 
    DoProcB; 
    {other stuff} 
    except 
    on E: Exception do 
    begin 
     Ex := E; 
     repeat 
     if Ex is MyException then 
      LogError ('Failure in ' + MyException(Ex).WhichFunc + ': ' + Ex.Message) 
     else 
      LogError ('Failure somewhere else: ' + Ex.Message); 
     Ex := Ex.InnerException; 
     until Ex = nil; 
    end; 
    end; 
end. 

Answer 2

Лучший способ справиться с этим, чтобы удалить все из этих обработчиков исключений. Используйте библиотеку, такую ​​как madExcept, EurekaLog, JCL Debug и т. Д. Для регистрации любых исключений, которые полностью возвращаются к обработчику исключений верхнего уровня.

Это просто несостоятельно для вас, чтобы попытаться добавить обработчик исключений для каждой функции в вашей программе. Это совсем не так, как предполагается использование исключений. Как правило, вы должны рассматривать исключения как вещи, которые не должны быть пойманы. Они представляют собой исключительное поведение, и, как правило, обычно бывает, что функция, в которой они созданы, не знает, как с ними бороться.

Итак, перестаньте обрабатывать исключения. Не обращайтесь с ними, как руководящий принцип. Если они дойдут до верхнего уровня обработчика исключений, побеседуйте с ними. И если вы используете одну из вышеупомянутых библиотек, вы сможете получить богатую отладочную информацию, чтобы помочь вам понять, почему в первую очередь возникло исключение.

Answer 3

Разработчики с других языков тратят много времени и энергии на беспокойство об «необработанных исключениях», но в типичном приложении форм Delphi, если вы посмотрите на код, стоящий за Application.Run, вы увидите, что все исключения будут обработаны, если вы пусть они пузырятся до самого верха. (Что является предпочтительным поведением, если у вас нет оснований вмешиваться)

Довольно часто рекомендуется добавлять дополнительную информацию в исключение, а затем повторно поднимать ее, т.е. отпусти ситуацию. Что-то пошло не так, ваша функция вызова должна знать, и в этом и заключается цель исключения.

Если вы хотите регистрировать каждую ошибку, тогда хорошее место для этого было бы в событии Application.OnException. NB. ваш пример - это приложение командной строки в стиле DOS, а не типичное приложение для форм Windows Delphi, не уверен, что это то, что вы намеревались.Если бы это было просто для того, чтобы попытаться упростить пример, вы фактически создали больше работы для себя, так как у вас нет доступа к объекту Application и всем функциям, которые с ним связаны.

Например.

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    Application.OnException := AppException; 
end; 

procedure TForm1.AppException(Sender: TObject; E: Exception); 
begin 
    if RunningInAutomationMode then 
    begin 
     LogError(E.Message); 
     Application.Terminate; 
    end 
    else 
    Application.ShowException(E); 

end; 

Чтобы ответить на ваш вопрос прямо, хотя:

Procedure DoProcA; 
begin 
    try 
    {stuff}; //stuff that might fall 
    except 
    on E : Exception do 
    begin 
     //LogError ('error in A'); will get logged later, don't want to log twice 
     E.Message := 'The following error occurred while trying to do whatzit to a whozit: '+E.Message; 
     raise; 
    end; 
    end; 
end; 

Procedure DoProcB; 
begin 
    try 
    DoProcC; //another proc that might fail 
    {other stuff} 
    except 
    on E : Exception do 
    begin 
     //LogError ('error in B'); 
     E.Message := E.Message + ' (Proc B)'; 
     raise; 
    end; 
    end; 
end; 

Procedure DoProcC; 
begin 
    try 
    {Do stuff} //even more stuff that might fail 
    except 
    on E : Exception do 
    begin 
     //LogError ('error in C'); 
     E.Message := 'The following error occurred during procedure C: '+E.Message; 
     raise; //Note: do not use raise Exception.Create(E.Message); as you will then lose the exception's type, which can be very useful information to have 
    end; 
    end; 
end; 

begin 
    try 
    DoProcA; 
    DoProcB; 
    {other stuff} 
    except 
    on E: Exception do 
    begin 
     LogError (E.Message); //this will end up logging all the exceptions, no mater which procedure they occurred in 
     //Exception has not been re-raised, so code will continue from this point 
     Exit; 
    end; 
    end; 

{Some more code} //Called exit above, so that this code won't get called, although it is unlikely you'll have more code outside the try..except block 

end.