Perl - значение объекта не сохранено

Question

Попытка получить поддержку использования ООП в Perl. Моя проблема в том, что я устанавливаю переменную в классе, но значение теряется, когда я пытаюсь ее восстановить. Я уверен, что проблема вопиющая, но мне нужны дополнительные глаза.

Конструктор:

sub new 
{ 
    my ($class, $name) = @_; 
    my $self = { 
     _name => $name, 
     _times => [] 
    }; 
    bless ($self, $class); 
    return $self; 
} 

аксессор Метод/мутатором:

sub times { 
    my ($self) = shift; 
    if (@_) { @{$self->{_times}} = shift } 
    print "times size: " . @{$self->{_times}} . "\n"; 
    return @{$self->{_times}}; 
} 

вызова из основной программы:

$js->addRun($duration, $curStartTime); 
print "Times size: " . @{$js->times()} . "\n"; 

соответствующий код из addRun() подпрограмма:

sub addRun { 
    my ($self, $duration, $runDateTime) = @_; 
    if (!defined($duration) || !defined($runDateTime)) { return 0; } 
    push(@{$self->{_times}},$duration); 
} 

Когда я запускаю этот код, он входит в подпрограмму addRun и толкает значение переменной _times. Затем я печатаю значение, вызывая accessor/mutator. Но у аксессора/мутатора есть своя команда печати, поэтому я могу проверить значение, прежде чем возвращать его.

Аксессор печатает правильное значение, но когда я печатаю то, что было возвращено, оно не определено. Я где-то перепутал мой синтаксис? Я просто идиот?

Благодаря

Answer 1

Проблемы в ваши раз (а) подпрограмме вы возвращаете массив, а не ссылки на массив.

Затем в вашей основной программе вы пытаетесь разыменовать вызов в times(), но вам не нужно.

Так в основной программе просто назвать его следующим образом: -

print "Times size: " . $js->times() . "\n"; 

Answer 2

Я попробовал ваш код use strict; включен и получил Can't use string ("1") as an ARRAY ref while "strict refs" in use.

Это имел в виду линии: print "Times size: " . @{$js->times()} . "\n";

Метод times возвращает массив значений. Когда вы разыскиваете возвращаемое значение раз, вы даете ему скалярный контекст. Таким образом, массив оценивается, чтобы указать количество членов в массиве, то есть 1. Таким образом, вы пытаетесь получить доступ к @ '1', которого не существует.

Вот очищенная версия вашего кода. У вас было пару ошибок (это было невозможно когда-либо массив длины> 1 при установке с помощью метода times.

#!/usr/bin/perl 

use strict; 
use warnings; 

my $foo = Foo->new('Pogo'); 

$foo->addRun(10, time); 
$foo->addRun(20, time); 
print "Times: ", join(' ', $foo->times), "\n"; 
print "Times length: " . $foo->times . "\n"; 


BEGIN { 
    package Foo; 

    sub new { 
     my ($class, $name) = @_; 
     my $self = { 
      _name => $name, 
      _times => [], 
     }; 
     bless $self, $class; 
     return $self; 
    } 

    sub times { 
     my $self = shift; 
     if (@_) { 
      my $time_array = shift; 
      @{$self->{_times}} = @{$time_array}; 
     } 
     return @{$self->{_times}}; 
    } 

    sub add_times { 
     my $self = shift; 
     return push @{$self->{_times}}, @_; 
    } 

    sub addRun { 
     my ($self, $duration, $runDateTime) = @_; 

     return 0 unless defined($duration) and defined($runDateTime); 

     $self->add_times($duration); 
    } 

}