Переименование файлов * .nfo в соответствии с их * .mkv's

Question

Попытка организовать показы * .nfo файлов, чтобы они имели то же имя, что и mkv (Edit: avi woops на самом деле не меняют код), которые они соответствуют.

Test Folder: 
76107.2.1.nfo 
76107.2.2.nfo 
76107.2.3.nfo 
Doctor Who - S02E01 (009) - Planet of Giants (1) - Planet of Giants.avi 
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.avi 
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.avi 

Теперь число эпизодов в 76107.2. *. NFO неверны в более поздних папках схожесть в папке тест только потому, что это первый в сезоне. поэтому я не могу просто сравнивать имена для их соответствия, но они находятся в правильном порядке, поэтому я пытаюсь использовать счетчики, чтобы переименовать первый * .nfo так же, как и первый * .avi, а затем второй * .nfo. то же, что и второй * .avi и так далее!

Я сделал сценарий, который, как я думал, должен работать, но он ничего не делает. Любая помощь приветствуется! Редактировать Теперь он работает благодаря Aacini, за исключением странной ошибки, отмеченной в коде.

@echo on 
setlocal enableDelayedExpansion 

set cnta=0 
Set cntb=0 
for %%b in (*.avi) do (
set /a cnta=cnta+1 
set line_!cnta!=%%~Nb 
) 

for %%c in (*.nfo) do (
set /a cntb=cntb+1 
for %%i in (!cntb!) do ren "%%~fc" "!line_%%i!.nfo" 
) 

Ошибка: первое nfo, похоже, попало в конец списка, но его место все еще сохраняется. Как и в любом другом nfo, имя соответствует соответствующему avi.

Test 1 (Original Test Folder) Results: 
.nfo 
Doctor Who - S02E01 (009) - Planet of Giants (1) - Planet of Giants.avi 
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.avi 
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.nfo 
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.avi 
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.nfo 

Test 2 (Added Extra Bonus File) Results: 
Doctor Who - S02E01 (009) - Planet of Giants (1) - Planet of Giants.avi 
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.avi 
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.nfo 
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.avi 
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.nfo 
Doctor Who - S02E01 (009) - Planet of Giants (4) - The Making of Planet of Giants.avi 
Doctor Who - S02E01 (009) - Planet of Giants (4) - The Making of Planet of Giants.nfo 

Некоторые папки будут содержать бонусные видео в конце списка, которые не имеют соответствие NFO, но они всегда в конце. Я прочитал nfo, чтобы проверить только «.nfo» (Test 1)/«Doctor Who - S02E01 (009) -« Планета гигантов »(4) -« Создание планеты гигантов »(тест 2) были неуместны, они должны были из «Доктор Кто - S02E01 (009) - Планета гигантов (1) - Планета гигантов.nfo»

Answer 1

Правильный термин для обозначения ваших переменных line_!cnta!: массив. Вы можете просмотреть полное описание управления массивами в пакетных файлах по адресу this post. Например, код может быть закреплен таким образом:

EDIT: небольшой ошибки фиксированной

@echo on 
setlocal enableDelayedExpansion 

set cnta=0 
Set cntb=0 

for %%b in (*.mkv) do (
set /a cnta=cnta+1 
set line_!cnta!=%%~Nb 
) 

for /F "delims=" %%c in ('dir /B *.nfo') do (
set /a cntb=cntb+1 
for %%i in (!cntb!) do ren "%%~fc" "!line_%%i!.nfo" 
) 

Answer 2

Я думаю, что это сработает для вас. Вы должны изменить echo ren на ren, как только вы решите, что он выглядит правильно.

@echo on 
setlocal enableDelayedExpansion 

set cnta=0 
set cntb=0 

for %%a in (*.mkv) do (
    set /a cnta=cnta+1 
    set line_!cnta!=%%a 
) 

for %%b in (*.nfo) do (
    set /a cntb=cntb+1 
    set newname=line_!cntb! 
    call set newname=%%!newname!%% 
    echo ren "%%~fb" "!newname!" 
) 

Я думаю, вы предпочтете такую ​​петлю. Я тестировал все это на этот раз:

@echo on 
setlocal enableDelayedExpansion 

set cnta=0 
set cntb=0 

for /f "usebackq delims=" %%a in (`dir *.mkv /a-d /b /on`) do (
    set /a cnta=cnta+1 
    set line_!cnta!=%%a 
) 

for /f "usebackq delims=" %%b in (`dir *.nfo /a-d /b /on`) do (
    set /a cntb=cntb+1 
    set newname=line_!cntb! 
    call set newname=%%!newname!%% 
    echo ren "%%~fb" "!newname!" 
) 

Если у вас есть какие-либо реальные интерес к игре с помощью пакетных сценариев, вы собираетесь нужно много терпения, и методом проб и ошибок, прежде чем он действительно начинает щелкать. Это может быть очень сложным и сложным.

Answer 3

Так как вы, кажется, ищете альтернативу, делает каждый .nfo файл содержит имя его соответствующий файл .mkv? Если это так, вы можете использовать find и условное выполнение для сопряжения .mkv с его .nfo содержимым .nfo. Это много (much!) менее эффективен, чем ответы Шон и Ачини, но по крайней мере вам не нужно беспокоиться о том, будут ли файлы в порядке.

@echo off 
setlocal 

for %%I in (*.mkv) do (
    for %%x in (76107*.nfo) do if not exist "%%~nI.nfo" (
     find /i "%%~nxI" "%%x" >NUL && ren "%%x" "%%~nI.nfo" 
    ) 
)