Пользовательская группировка в xsl

Question

Привет, У меня есть проблема, требующая довольно специализированной сортировки и хотелось бы получить обратную связь по наилучшему подходу. Вот некоторые XML:

<root> 
    <locations> 
    <location> 
     <address>123 4 st Smallville</address> 
     <number>1</number> 
    </location> 
    <location> 
     <address>432 1 st Metropolis</address> 
     <number>2</number> 
    </location> 
    </locations> 
    <insuranceCoverages> 
    <coverage> 
     <name>General Coverage</name> 
     <locationSplits> 
     <coverage> 
      <name>Building Coverage</name> 
      <locationNumber>1</locationNumber> 
      <clauses> 
      <coverage> 
       <name>Earthquake Exclusion</name> 
      </coverage> 
      </clauses> 
     </coverage> 
     </locationSplits> 
    </coverage> 
    <coverage> 
     <name>General Liability</name> 
    </coverage> 
    </insuranceCoverages> 
</root> 

Что я хотел бы сделать, это групповые охваты от места в довольно плоскую иерархию. Что-то вроде:

┌Location 1 
├┬Coverage "Building Coverage" 
│└Coverage "Earthquake Exclusion" 
├Location 2 
├No Location 
├┬Coverage "General Coverage" 
│└Coverage "General Liability" 

моего текущего решения использует шаблон на места/месте и перечисляет список покрытий, которые ищут номер места, которое соответствует текущему местоположению. Однако, поскольку этот алгоритм перебирает все охваты для каждого места, это

O(nm) 
    where n = # locations + 1 
     m = # coverages 

Я бы предпочел, если мой алгоритм может быть оптимизирован для обхода дерева покрытий только один раз, помещая каждое покрытие в виде набора на основе текущего местоположения себя или своих предков, а затем распечатывать эти наборы.

O(n) 
    where n = # coverages 

Конечно, если есть более эффективные способы выражения этого с помощью XSL (возможно с XSL: для-каждой группы инструкции) мне было бы интересно услышать о том, что слишком.

Answer 1

если есть более эффективные способы выражения этого с XSL,

Эффективный способ сделать это с помощью XSLT - это использовать key. Вот простой пример:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:key name="coverage-by-location" match="coverage" use="locationNumber" /> 

<xsl:template match="/root"> 
    <xsl:copy> 
     <xsl:for-each select="locations/location"> 
      <location number="{number}"> 
       <xsl:for-each select="key('coverage-by-location', number)"> 
        <coverage name="{name}"/> 
       </xsl:for-each> 
      </location> 
     </xsl:for-each> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet> 

Это проходит только расположение/расположение ветви дерева, и использует индекс, созданный <key> инструкции для того, чтобы отобрать охваты, соответствующие значению Текущее местоположение.

Добавление другой ветви «Нет места» для вывода дерева немного сложнее, но может быть сделано путем изменения ключа к:

<xsl:key name="coverage-by-location" match="coverage" use="string(locationNumber)" /> 

На данный момент, это будет более удобно иметь один шаблон для обработки покрытий обоих видов, так:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:key name="coverage-by-location" match="coverage" use="string(locationNumber)" /> 

<xsl:template match="/root"> 
    <xsl:copy> 
     <xsl:apply-templates select="locations/location"/> 
     <no-location> 
      <xsl:apply-templates select="key('coverage-by-location', '')"/> 
     </no-location> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="location"> 
    <location number="{number}"> 
     <xsl:apply-templates select="key('coverage-by-location', number)"/> 
    </location> 
</xsl:template> 

<xsl:template match="coverage"> 
    <coverage name="{name}"/> 
</xsl:template> 

</xsl:stylesheet> 

Применяя это к вашей входной examp ле будет возвращаться:

<?xml version="1.0" encoding="UTF-8"?> 
<root> 
    <location number="1"> 
     <coverage name="Building Coverage"/> 
    </location> 
    <location number="2"/> 
    <no-location> 
     <coverage name="General Coverage"/> 
     <coverage name="Earthquake Exclusion"/> 
     <coverage name="General Liability"/> 
    </no-location> 
</root> 

, который немного отличается от результата вы ожидали, но не объясняет, как именно покрытие «Earthquake исключения» будет ассоциироваться с позицией # 1.

---

EDIT:

Что касается исключения землетрясения, это очень важно для того, чтобы в конечном итоге под элементом место 1, поскольку он является потомком другого покрытия на месте 1.

в таком случае, я считаю, что было бы лучше, чтобы изменить ключ:

<xsl:key name="coverage-by-location" match="coverage" use="string(ancestor-or-self::coverage/locationNumber)" /> 

Answer 2

Я не уверен, если этот подход достаточно эффективен - с помощью шаблона, который соответствует каждому location с number сопрягать locationNumber дочерний элемент locationSplits

<xsl:template match="location[number=//coverage//locationNumber]"> 

и второй шаблон, соответствующий любой другой location, то следующий XSLT

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output method="xml" omit-xml-declaration="yes" encoding="UTF-8" indent="yes" /> 
    <xsl:strip-space elements="*" /> 
    <xsl:template match="insuranceCoverages"> 
     <xsl:apply-templates /> 
    </xsl:template> 
    <xsl:template match="@*|node()"> 
     <xsl:apply-templates select="@*|node()" /> 
    </xsl:template> 
    <xsl:template match="location[number=//coverage//locationNumber]"> 
     <xsl:variable name="number" select="number" /> 
     <xsl:text>Location</xsl:text> 
     <xsl:value-of select="$number" /> 
     <xsl:text>Coverage:</xsl:text> 
     <xsl:value-of select="//locationSplits//coverage[locationNumber=$number]/name" /> 
     <xsl:for-each select="//locationSplits//coverage[locationNumber=$number]/clauses/coverage"> 
     <xsl:text>Coverage:</xsl:text> 
     <xsl:value-of select="name" /> 
    </xsl:for-each> 
    </xsl:template> 
    <xsl:template match="location"> 
    <xsl:variable name="number" select="number" /> 
    <xsl:text>Location</xsl:text> 
    <xsl:value-of select="$number" /> 
    <xsl:text>No Location</xsl:text> 
    <xsl:for-each select="//insuranceCoverages//coverage[not(ancestor::locationSplits)]"> 
     <xsl:text>Coverage:</xsl:text> 
     <xsl:value-of select="name" /> 
    </xsl:for-each> 
    </xsl:template> 
</xsl:stylesheet> 

применительно к вашей входной XML производит вывод

Location 1 
Coverage: Building Coverage 
Coverage: Earthquake Exclusion 
Location 2 
No Location 
Coverage: General Coverage 
Coverage: General Liability 

Я не уверен, что возможны несколько статей для покрытий в locationSplits, поэтому, возможно, нет необходимости их перегибать.
шаблон соответствия location без coverage в locationSplits просто печатает каждый coverage дочерний элемент insurangeCoverages, что не имеет какого-либо дочерний элемент locationSplits:

<xsl:for-each select="//insuranceCoverages//coverage[not(ancestor::locationSplits)]">