Простой способ форматирования даты

Question

Я написал скрипт perl для получения даты и времени. Это действительно работает, но я задаюсь вопросом, есть ли более простой способ форматирования даты в качестве вывода.

#!/usr/bin/perl 
use DateTime; 

my $dt   = DateTime->now(time_zone => 'local'); 
$myTimeStamp = $dt->subtract(days => 1); 
$myYear   = $myTimeStamp->year; 
$myMonth  = $myTimeStamp->month; 
if (length($myMonth) == 1) { 
    $myMonth = "0$myMonth"; 
} 
$myDay   = $myTimeStamp->day; 
if (length($myDay) == 1) { 
    $myDay = "0$myDay"; 
} 
$myHour   = $myTimeStamp->hour; 
if (length($myHour) == 1) { 
    $myHour = "0$myHour"; 
} 
#$myDir   = "/var/tmp/logs/$myYear/$myMonth/$myYear$myMonth-"; 

print "--> $myYear $myMonth $myDay $myHour\n"; 
# --> 2012 02 28 02 
exit 0; 

Answer 1

DateTime предоставляет метод format_cldr для этого:

use DateTime; 

my $myTimeStamp = DateTime->now->subtract(days => 1); 

printf "--> %s\n", $myTimeStamp->format_cldr('yyyy MM dd HH'); 
# --> 2012 02 28 02 

Answer 2

Конечно, использовать POSIX модуль:

Модуль POSIX позволяет вам получить доступ ко всем (или почти все) стандартные идентификаторы в POSIX 1003.1.

Пример:

use POSIX; 
print POSIX::strftime('%d-%m-%Y %H:%M:%S', localtime()); 

Answer 3

• Прежде всего всегдаuse strict; и use warnings; в начале вашей программы и объявить все ваши переменные близки к их первым использовать. Это особенно важно, если вы ищете помощь, поскольку она найдет много простых ошибок, которые не сразу очевидны.

Лучше всего использовать printf, если вы хотите получить нуль-площадку любого выхода. Также нет необходимости извлекать поля даты для разделения переменных. На выходе вы показали тот, который вам в конечном итоге нужен? Эта программа делает то же самое, что и код, который вы опубликовали.

use strict; 
use warnings; 

use DateTime; 

my $myTimeStamp = DateTime->now->subtract(days => 1); 
printf "--> %04d %02d %02d %02d\n", map $myTimeStamp->$_, qw/year month day hour/; 

ВЫВОД

--> 2012 02 28 12 

Answer 4

Для дат повторного форматирования, как уже отмечалось, есть POSIX модуль ядра. Вам не нужно было бы также смотреть на основной модуль Time::Piece, который не только доставляет strftime(), но также и strptime(), чтобы обеспечить очень гибкий синтаксический анализ даты и времени. Time::Piece появился в ядре Perl в 5.9.5.