РЕШЕНИЕ ПОИСКА QUERY

Question

Я делаю поисковый запрос для использования в форме под названием «ClassProfile». Форма является непрерывной формой и поэтому перечисляет записи в формате данных. У меня есть два текстовых полей на форме:

1. clsBox - используется для ввода имени класса Е.Г. 1T
2. nameBox - используется для ввода имени учителя, например, Джо

Оба эти текстовые поля будут использоваться пользователем для выполнения различных поисков на основе значений, содержащихся в них. Рядом с ними находится командная кнопка с надписью «Поиск». OnClick() событие кнопки поиска содержит следующий код для выполнения поиска:

Private Sub cmdSearch_Click() 

Dim strsearching As String 
Dim strm As String 
Dim tname As String 

strm = Me.clsBox.Value 
tname = Me.NameBox.Value 

If Not IsNull(strm) Then 
    If IsNull(strsearching) Then 
    strsearching = "(([ClassProfile].[Class]) LIKE ""*" & strm & "*"")" 
    End If 
Else: strsearching = "" 
End If 

If Not IsNull(tname) Then 
    If Not IsNull(strsearching) Then 
    strsearching = strsearching & " AND (([ClassProfile].[Class Teacher]) LIKE ""*" & tname & "*"")" 
    Else: strsearching = "(([ClassProfile].[Class Teacher]) LIKE ""*" & tname & "*"")" 
    End If 
Else: strsearching = "" 
End If 

Dim sql As String 

If Not IsNull(strsearching) Then 
    sql = "SELECT * FROM [ClassProfile] WHERE " & strsearching 
    Else: sql = "ClassProfile" 
End If 

Me.RecordSource = sql 

End Sub 

Когда не выполняет поиск ничего не происходит с записями формы, знак код не работает. Любая помощь приветствуется.

Answer 1

ОБНОВЛЕНО: Изменены проверки ISNULL (strsearching). Вот что-то работает. Я изменил ваши Null-проверки, чтобы не иметь дело с иногда нулевыми значениями.

Option Compare Database 
Option Explicit 

Private Sub cmdSearch_Click() 

Dim strsearching As String 
Dim strm  As String 
Dim tname  As String 
Dim sql   As String 

    strm = Nz(Me.clsBox.Value) 
    tname = Nz(Me.NameBox.Value) 

    strsearching = "" 
    If strm <> "" Then 
     strsearching = "(([ClassProfile].[Class]) LIKE ""*" & strm & "*"")" 
    End If 

    If tname <> "" Then 
     If strsearching <> "" Then 
      strsearching = strsearching & " AND (([ClassProfile].[Class Teacher]) LIKE ""*" & tname & "*"")" 
     Else 
      strsearching = "(([ClassProfile].[Class Teacher]) LIKE ""*" & tname & "*"")" 
     End If 
    End If 

    If strsearching <> "" Then 
     sql = "SELECT * FROM [ClassProfile] WHERE " & strsearching 
    Else 
     sql = "ClassProfile" 
    End If 

    Debug.Print sql 

    Me.RecordSource = sql 

End Sub 

Answer 2

Работы как шарм Уэйн. Все комплименты вам. Модифицированный это просто немного точности, вот окончательный код:

strm = Me.clsBox.Value 
tname = Me.NameBox.Value 

strsearching = "" 
If Len(Trim(Me.clsBox.Value)) <> 0 Then 
    strsearching = "(([ClassProfile].[Class]) LIKE ""*" & strm & "*"")" 
End If 

If Len(Trim(Me.NameBox.Value)) <> 0 Then 
    If strsearching <> "" Then 
    strsearching = strsearching & " AND (([ClassProfile].[Class Teacher]) LIKE ""*" & tname & "*"")" 
    Else: strsearching = "(([ClassProfile].[Class Teacher]) LIKE ""*" & tname & "*"")" 
    End If 
End If 

Dim sql As String 

If strsearching <> "" Then 
    sql = "SELECT * FROM [ClassProfile] WHERE " & strsearching 
    Else: sql = "ClassProfile" 
End If 

Me.RecordSource = sql