Как запустить определенную версию Xcode из Applescript?

Question

У меня есть две версии Xcode, Xcode 3.2.3 и предварительный просмотр разработчика Xcode4. Как обеспечить из Applescript, что выбрана версия 3.2.3?

Answer 1

Вместо того, чтобы просто ссылки Xcode по его имени, то есть:

tell application "Xcode" 
    ... 
end tell 

вы можете также ссылаться на конкретную версию приложения на полный путь к POSIX, а именно:

tell application "/Developer/Applications/Xcode 3.2.3.app" 
    ... 
end tell 

Смотрите также Раздел руководства по языку AppleScript на странице application class.

Более сложное решение включает поиск базы данных служб запуска для всех версий приложения, установленных в системе. Затем вы можете программно выбрать один вариант с требуемой версией:

property pLSRegisterPath : "/System/Library/Frameworks/CoreServices.framework/Versions/A/Frameworks/LaunchServices.framework/Versions/A/Support/lsregister" 
property pAppBundleID : "com.apple.Xcode" 
property pAppRequiredVersion : "3.2.3" 

set theAppPaths to every paragraph of (do shell script pLSRegisterPath & " -dump | grep --before-context=2 \"" & pAppBundleID & "\" | grep --only-matching \"/.*\\.app\"") 

set xcodeApp to missing value 
repeat with theAppPath in theAppPaths 
    try 
     if (version of application theAppPath) = pAppRequiredVersion then 
      set xcodeApp to application theAppPath 
      exit repeat 
     end if 
    end try 
end repeat 

if xcodeApp = missing value then 
    error "Needed application version not installed." 
end if 

using terms from application "Xcode" 
    tell xcodeApp 
     activate 
    end tell 
end using terms from 

Answer 2

Вы можете запустить приложение по его идентификатору, как это. Возможно, у двух версий будут разные идентификаторы.

tell application id "com.apple.AddressBook" 
    -- do something 
end tell 

Вы можете получить идентификатор приложения, с помощью этого ...

tell application "Finder" to return id of (choose file)