Курсор курсора SQL Server не работает

Question

Я создал курсор внутри триггера и не работает должным образом. Пожалуйста, помогите мне исправить

Create trigger Posts_Raw_To_Queue_Trigger ON SendNotificationPostsRaw FOR INSERT 
AS 
BEGIN 

DECLARE @PostID uniqueidentifier 
DECLARE @UserID uniqueidentifier 
DECLARE @ProfID int 
DECLARE @Email nvarchar(100) 
DECLARE @CreationTime datetime 
DECLARE @SpecialityID int 

SELECT @ProfID= ProfessionalID,@Email= Email from Professionals where UserID=@UserID 
SELECT @PostID = I.PostID,@UserID = I.UserID ,@CreationTime =I.CreationTime FROM INSERTED I 

DECLARE post_relation_cursor CURSOR FOR select CategoryId from PostCategoryRelations where PostId=@PostID; 

OPEN post_relation_cursor; 
FETCH NEXT FROM post_relation_cursor INTO @SpecialityID 
WHILE @@FETCH_STATUS = 0 
BEGIN 
     INSERT INTO SendNotificationPostsQueue (UserID,PostID,SpecialityID,TemplateID,CreationTime,SendTime,JSONParameters) Values(@UserID,@PostID,1,1,'04/11/2013','04/11/2013','') 

     FETCH NEXT FROM post_relation_cursor INTO @SpecialityID; 
END; 
CLOSE post_relation_cursor; 
DEALLOCATE post_relation_cursor; 

END 

Если удалить курсор и вставьте фиктивные значения в SendNotificationPostsQueue, он работает. Так что проблема с моим курсором ... Скажите, пожалуйста, почему курсор не работает?

Answer 1

Это Безразлично» t кажется, что вам нужно использовать курсор на всех, и было бы лучше не используя один почти во всех случаях. Просто замените корпус вашего триггера (часть между начала и конца) со стандартной вставки:

INSERT INTO SendNotificationPostsQueue (UserID,PostID,SpecialityID,TemplateID,CreationTime,SendTime,JSONParameters) 
SELECT 
    i.UserID, 
    i.PostID, 
    1, 
    1, 
    '04/11/2013', -- Might want i.CreationTime or current_timestamp 
    '04/11/2013', 
    '' 
FROM INSERTED i 
    -- possibly want "LEFT JOIN Professionals p on i.UserID = p.UserID" here to grab other info 

Обратите внимание, как я не использую в положение режущей пластины, которая может только вставить одну строку values. Я помещаю оператор select как часть вставки, таким образом, вставляя столько строк, сколько возвращает select. Это означает, что нам не нужно использовать курсор, и вам не нужна куча переменных для включения курсора.

Одна проблема с вашим текущим кодом, как упомянуто в @automatic, заключается в том, что вы предполагаете, что INSERTED содержит только одну строку. Если он имеет более одного, то вы будете бросать ошибку при попытке присвоить столбец переменной.

Из-за элегантности, ремонтопригодности и производительности я настоятельно рекомендую вам отказаться от этого курсора и запустить простую вставку (так как это все, что делает ваш курсор в любом случае).

Answer 2

Возможная проблема здесь -

CREATE TRIGGER dbo.Posts_Raw_To_Queue_Trigger 

    ON SendNotificationPostsRaw 
    -- for view 
    INSTEAD OF INSERT 
    -- OR 
    -- for table 
    AFTER INSERT 

AS BEGIN 

    DECLARE 
      @PostID UNIQUEIDENTIFIER 
     , @UserID UNIQUEIDENTIFIER 
     , @ProfID INT 
     , @Email NVARCHAR(100) 
     , @CreationTime DATETIME 
     , @SpecialityID INT 

    SELECT @ProfID = ProfessionalID 
     , @Email = Email 
    FROM Professionals 
    WHERE UserID = @UserID 

    -- this posible return invalid result (random record from inserted sequence) 
    SELECT @PostID = I.PostID 
     , @UserID = I.UserID 
     , @CreationTime = I.CreationTime 
    FROM INSERTED I 

    DECLARE post_relation_cursor CURSOR LOCAL READ_ONLY FAST_FORWARD FOR 
     SELECT CategoryID 
     FROM dbo.PostCategoryRelations 
     WHERE PostId = @PostID; 

    OPEN post_relation_cursor; 

    FETCH NEXT FROM post_relation_cursor INTO @SpecialityID 

    WHILE @@FETCH_STATUS=0 BEGIN 

     INSERT INTO SendNotificationPostsQueue (
       UserID 
      , PostID 
      , SpecialityID 
      , TemplateID 
      , CreationTime 
      , SendTime 
      , JSONParameters 
     ) 
     SELECT 
       @UserID 
      , @PostID 
      , @SpecialityID --- !!! 
      , 1 
      , '04/11/2013' 
      , '04/11/2013' 
      , '' 


     FETCH NEXT FROM post_relation_cursor INTO @SpecialityID; 

    END; 

    CLOSE post_relation_cursor; 
    DEALLOCATE post_relation_cursor; 

END 

---

Update

Если я вас правильно понимаю, бизнес-логика должна быть такой:

CREATE TRIGGER dbo.Posts_Raw_To_Queue_Trigger 

    ON dbo.SendNotificationPostsRaw 
    [INSTEAD OF]/[AFTER] INSERT 

AS BEGIN 

    SET NOCOUNT ON; 

    DECLARE 
      @PostID UNIQUEIDENTIFIER 
     , @UserID UNIQUEIDENTIFIER 
     , @ProfID INT 
     , @Email NVARCHAR(100) 
     , @CreationTime DATETIME 
     , @SpecialityID INT 

    DECLARE cur CURSOR LOCAL READ_ONLY FAST_FORWARD FOR 
     SELECT 
       i.PostID 
      , i.UserID 
      , ProfID = p.ProfessionalID 
      , p.Email 
      , i.CreationTime 
      , pcr.CategoryID 
     FROM INSERTED i 
     JOIN dbo.Professionals p ON i.UserID = p.UserID 
     JOIN dbo.PostCategoryRelations pcr ON i.PostID = pcr.PostID 

    OPEN cur 

    FETCH NEXT FROM cur INTO 
      @PostID 
     , @UserID 
     , @ProfID 
     , @Email 
     , @CreationTime 
     , @SpecialityID 

    WHILE @@FETCH_STATUS = 0 BEGIN 

     INSERT INTO dbo.SendNotificationPostsQueue 
     (
       UserID 
      , PostID 
      , SpecialityID 
      , TemplateID 
      , CreationTime 
      , SendTime 
      , JSONParameters 
     ) 
     SELECT 
       @UserID 
      , @PostID 
      , @SpecialityID 
      , 1 
      , @CreationTime 
      , @CreationTime 
      , '' 

     FETCH NEXT FROM cur INTO 
       @PostID 
      , @UserID 
      , @ProfID 
      , @Email 
      , @CreationTime 
      , @SpecialityID 

    END 

    CLOSE cur 
    DEALLOCATE cur 

END