Не удается запустить оператор if в вложенном цикле в xslt

Question

Я использую xslt для преобразования моего xml таким образом, что в теге отображаются только те элементы, которые отображаются в теге <AffectedItems>. <Changes>. Я новичок в xslt, поэтому, пожалуйста, расскажите, что я делаю неправильно здесь.
Вот XML:

<Product> 
    <Items> 
     <Item itemIdentifier="1102607"> 
     </Item> 
     <Item itemIdentifier="1890456"> 
     </Item> 
    </Items> 
    <Changes> 
     <Change> 
     <AffectedItems> 
      <AffectedItem itemIdentifier="1102607"> 
      </AffectedItem> 
     </AffectedItems> 
     </Change> 
    </Changes> 
</Product> 

Вот соответствующая часть в XSLT в:

<xsl:for-each select="Product"> 
    <xsl:variable name="var3_current" select="."/> 
    <Items> 
    <xsl:for-each select="Items/Item"> 
     <xsl:for-each select="Changes/Change/AffectedItems/AffectedItem"> 
     <xsl:if test="floor(@itemIdentifier) = floor(Changes/Change/AffectedItems/AffectedItem/@itemIdentifier)"> 
      <Item> 
      <xsl:attribute name="itemIdentifier"> 
      <xsl:value-of select="floor(@itemIdentifier)"/> 
      </Item> 
     </xsl:if> 
     </xsl:for-each> 
    </xsl:for-each> 
    </Items> 
    <Changes> 
    <Change> 
     <AffectedItems> 
     <AffectedItem> 
     <xsl:attribute name="itemIdentifier"> 
      <xsl:value-of select="floor(Changes/Change/AffectedItems/AffectedItem/@itemIdentifier)"/> 
     </AffectedItem> 
     </AffectedItems> 
    </Change> 
    </Changes> 
</xsl:for-each> 

Он проходит через все пункты, но не ставит ни в выходной XML. Таким образом, полученный xml имеет пустой тег элементов

<Items/> 

Answer 1

Основная проблема заключается в одном из контекстов. Вы начинаете с xsl:for-each на элементе Item, который позиционирует вас на этом элементе Item, но их вы делаете xsl:for-each на Changes. Это означает, что он ищет имена элементов Changes в качестве ребенка Item, но их нет. Таким образом, ваш вложенный xsl:for-each должен выглядеть следующим образом:

<xsl:for-each select="../../Changes/Change/AffectedItems/AffectedItem"> 

Однако, есть еще проблема с xsl:if в этом, как вы теперь расположены на AffectedItem, не Item вы были размещены на. Это означает, что ваш xsl:if проверяет itemIdentifier текущего AffectedItem против узла-потомка, начиная с Changes, которого нет.

Чтобы обойти эту проблему, ваш xsl:for-each должен выглядеть следующим образом

<xsl:for-each select="Items/Item"> 
    <xsl:variable name="Item" select="."/> 
    <xsl:for-each select="../../Changes/Change/AffectedItems/AffectedItem"> 
     <xsl:if test="floor(@itemIdentifier) = floor($Item/@itemIdentifier)"> 
      <Item> 
       <xsl:value-of select="floor(@itemIdentifier)"/> 
      </Item> 
     </xsl:if> 
    </xsl:for-each> 
</xsl:for-each> 

Однако, это на самом деле не является идеальным подходом. Здесь вам могут пригодиться две вещи. Во-первых, это использование Identity Transform для копирования существующих элементов. Во-вторых, используется xsl:key для поиска AffectedItem элементов.

По существу, преобразование идентичности копирует все как есть, тогда вам просто нужно добавить шаблон для соответствия Item элементам, для которых нет AffectedItem (который проверяется с помощью ключа).

Попробуйте это гораздо более простой XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output method="xml" /> 

    <xsl:key name="Affected" match="AffectedItem" use="number(@itemIdentifier)" /> 

    <xsl:template match="Item[not(key('Affected', number(@itemIdentifier)))]" /> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Я удалил использование floor в данном примере, так как я не мог понять, почему вы пол целый ряд.