Элементы прокрутки во время перетаскивания объекта

Question

После этого Qt tutorial Я написал этот простой код. Существует горизонтальный ListView с некоторым простым цветным прямоугольником на нем в качестве делегата для элементов модели.

import QtQuick 2.5 
import QtQuick.Window 2.0 
import QtQml.Models 2.2 

Window { 
    visible: true 
    width: 300 
    height: 120 
    title: qsTr("Hello World") 

    Rectangle { 
     anchors.fill: parent; 

     ListView{ 
      id: timeline 
      anchors.fill: parent 
      orientation: ListView.Horizontal 
      model: visualModel 
      delegate: timelineDelegate 

      moveDisplaced: Transition { 
       NumberAnimation{ 
        properties: "x,y" 
        duration: 200 
       } 
      } 

      DelegateModel { 
       id: visualModel 
       model: timelineModel 
       delegate: timelineDelegate 
      } 

      Component { 
       id: timelineDelegate 


       MouseArea { 
        id: dragArea 

        width: 100; height: 100 

        property bool held: false 

        drag.target: held ? content : undefined 
        drag.axis: Drag.XAxis 

        onPressAndHold: held = true 
        onReleased: held = false 

        Rectangle { 
         id: content 

         anchors { horizontalCenter: parent.horizontalCenter; verticalCenter: parent.verticalCenter } 
         width: 100 
         height: 100 

         color: colore 
         opacity: dragArea.held ? 0.8 : 1.0 

         Drag.active: dragArea.held 
         Drag.source: dragArea 
         Drag.hotSpot.x: width/2 
         Drag.hotSpot.y: height/2 

         states: State{ 
          when: dragArea.held 
          ParentChange { target: content; parent: timeline } 
          AnchorChanges { 
           target: content 
           anchors { horizontalCenter: undefined; verticalCenter: undefined } 
          } 
         } 
        } 

        DropArea { 
         anchors.fill: parent 
         onEntered: { 
          visualModel.items.move(drag.source.DelegateModel.itemsIndex, dragArea.DelegateModel.itemsIndex) 
          timeline.currentIndex = dragArea.DelegateModel.itemsIndex 
         } 
        } 
       } 
      } 

      ListModel { 
       id: timelineModel 
       // @disable-check M16 
       ListElement { colore: "blue" } 
       // @disable-check M16 
       ListElement { colore: "orange" } 
       // @disable-check M16 
       ListElement { colore: "red" } 
       // @disable-check M16 
       ListElement { colore: "yellow" } 
       // @disable-check M16 
       ListElement { colore: "green" } 
       // @disable-check M16 
       ListElement { colore: "yellow" } 
       // @disable-check M16 
       ListElement { colore: "red" } 
       // @disable-check M16 
       ListElement { colore: "blue" } 
       // @disable-check M16 
       ListElement { colore: "green" } 
      } 
     } 
    } 
} 

Если я нажать и удерживать на Item, я могу поменять его с другой стороны с хорошим движущемся эффектом.
Проблема начинается, когда в списке есть много предметов, а позиция цели находится за пределами видимых элементов. Я могу перетащить объявление товара, перемещая его рядом с правой или левой границей ... здесь движущийся эффект абсолютно не славный.

Есть ли наилучшая практика для правильной прокрутки списка, когда элемент приближается к границе?
Я бы хотел, чтобы прокрутка начиналась до того, как элемент касается границы!

Ниццкому один

Плохой один

Answer 1

ListView свитков, когда ListView.currentIndex изменяется. То есть, последняя строка в области падения:

timeline.currentIndex = dragArea.DelegateModel.itemsIndex 

говорит текущий индекс, который всегда виден, является перетаскивание элемента. Однако, если перетаскиваемый элемент получает границу, пользователь ожидает увидеть не только перетаскиваемый элемент, но и элемент рядом с ним. Поэтому вам нужно добавить еще один пункт к currentIndex:

timeline.currentIndex = dragArea.DelegateModel.itemsIndex + 1 

и теперь в виде списка правильно прокручивается вправо, если перетащить элемент на правой границе. Чтобы сделать его доступным как на левой, так и на правой границе, нам нужно добавить небольшую математику:

MouseArea { 
    id: dragArea 

    property int lastX: 0 
    property bool moveRight: false 

    onXChanged: { 
     moveRight = lastX < x; 
     lastX = x; 
    } 

    //.... 

    DropArea { 
     anchors.fill: parent 
     onEntered: { 
      visualModel.items.move(drag.source.DelegateModel.itemsIndex, 
            dragArea.DelegateModel.itemsIndex) 
      if (dragArea.moveRight) 
       timeline.currentIndex = dragArea.DelegateModel.itemsIndex + 1 
      else 
       timeline.currentIndex = dragArea.DelegateModel.itemsIndex - 1 
     } 
    } 
}