Отправьте строку в ее шестнадцатеричный эквивалент

Question

Я бы хотел отправить команды hex моему устройству, потому что он может понять только hex.

Из-за того, что мне удалось создать функцию, которая может проверить, если пользователи ввода, который является string имеет действующий соответствующий hex. Вопрос here.

Итак, подтвердив, что users input имеет соответствующий эквивалент hex, я уверен, что то, что отправит моя система, будет прочитано моим устройством. By searching я понял, что он должен быть преобразован в байты, говорится

Используйте класс ASCIIEncoding для convtert строки в массив байтов вы можете передавать.

Код:

Dim str as String = "12345678" 
Dim bytes() as Byte = ASCIIEncoding.ASCII.GetBytes(strNumbers) 
' Then Send te bytes to the reader 
sp.Write(bytes, 0, bytes.Length) 

Вам не нужно тайному значения в HEX, в этом случае HEX является mearly другой способ отображения то же самое.

Мой код:

'This is a string with corresponding hex value 
Dim msg_cmd as string = "A0038204D7" 
'Convert it to byte so my device can read it 
Dim process_CMD() As Byte = ASCIIEncoding.ASCII.GetBytes(msg_cmd) 
'Send it as bytes 
ComPort.Write(process_CMD, 0, process_CMD.Length) 

Мой выход:

41 30 30 33 38 32 30 34 44 37 

Желаемый результат:

A0 03 82 04 D7 

Answer 1

Чтобы отправить определенную последовательность байтов, не отправлять строка - просто отправьте байты:

Dim process_CMD() As Byte = { &HA0, &H03, &H82, &H04, &HD7 } 
ComPort.Write(process_CMD, 0, process_CMD.Length) 

Как я уже упоминал в приведенных выше замечаниях, значения представляют собой только числовые значения. Нет ничего особенного в гексагоне. Hex - это еще один способ представить одни и те же значения. Другими слова, код выше делает то же самое, как это:

Dim process_CMD() As Byte = { 160, 3, 130, 4, 215 } 
ComPort.Write(process_CMD, 0, process_CMD.Length) 

Если у вас есть шестнадцатеричные цифры в строке, вы можете преобразовать строковое представление шестнадцатеричного числа до значения байт с помощью appropriate overload метода Convert.ToByte. Тем не менее, это только преобразует один байт в то время, поэтому, сначала нужно разбить строку в байтах (две шестнадцатеричные цифры на байт, например:.

Dim input As String = "A0038204D7" 
Dim bytes As New List(Of Byte)() 
For i As Integer = 0 to input.Length Step 2 
    bytes.Add(Convert.ToByte(input.SubString(i, 2), 16) 
Next 
Dim process_CMD() As Byte = bytes.ToArray() 
ComPort.Write(process_CMD, 0, process_CMD.Length) 

Однако, было бы проще, если бы строка имела места . между байтами Тогда вы могли бы просто использовать String.Split метод:

Dim input As String = "A0 03 82 04 D7" 
Dim hexBytes As String() = input.Split(" "c) 
Dim bytes As New List(Of Byte)() 
For Each hexByte As String in hexBytes 
    bytes.Add(Convert.ToByte(hexByte, 16) 
Next 
Dim process_CMD() As Byte = bytes.ToArray() 
ComPort.Write(process_CMD, 0, process_CMD.Length) 

Или, более просто:

Dim input As String = "A0 03 82 04 D7" 
Dim process_CMD() As Byte = input.Split(" "c).Select(Function(x) Convert.ToByte(x, 16)).ToArray() 
ComPort.Write(process_CMD, 0, process_CMD.Length)