Невозможно прочитать символы строки внутри цикла for

Question

Я пытаюсь читать символы строки внутри цикла for.

Команда! String: ~ 1,3! работает отлично. Но могу ли я сделать это с помощью переменных вместо 1 и 3. Я попробовал следующий код, но я не знаю, что не так. Это не работает.

@echo off 
setlocal enableextensions enabledelayedexpansion 
set string=abcdefghij 
set /a count=1 
for /l %%x in (1,1,3) do (
    set string2=!string:~%count%,1! 
    set /a count+=1 
    echo !string2! 
    pause 
) 

, но он всегда дает выход как:

b 

Я хочу, чтобы выходной быть как:

b 
c 
d 

Просьба помочь в решении этого .. Большое спасибо заранее

Answer 1

Проблема заключается в том, что расширение %count% не задерживается, поэтому оно имеет одинаковое значение для каждого итерации цикла. Это лучше написано так:

@echo off 
setlocal enableextensions enabledelayedexpansion 
set string=abcdefghij 
set /a count=1 
for /l %%x in (%count%,1,3) do (
    set string2=!string:~%%x,1! 
    echo !string2! 
) 

---

Редактировать

Если вы хотите сохранить %count% оцениваются как переменная установлена, а не только в начале цикла for используйте Aacini's answer.

Answer 2

Для того, чтобы достичь того, чего вы хотите, вы должны сделать Delayed Expansion дважды, то есть, что-то вроде этого:

set string2=!string:~!count!,1! 

Конечно, предыдущая строка является недействительным. Хотя есть несколько способов решить эту проблему, большинство из них используют команду call, которая работает медленно. Чтобы исправить эту проблему, чтобы она выполнялась самым быстрым способом, используйте команду for, чтобы изменить первый! расширение в переменный параметр FOR, а затем использовать его в исходном выражении:

for %%i in (!count!) do set string2=!string:~%%i,1!