название графа отсутствует в ods pdf output

Question

options orientation=portrait; 
GOPTIONS device=ACTXIMG; 
options nocenter nodate nonumber; 

ods graphics/noborder width= 1200 height=360 scale; 
ods pdf startpage=never file="\\...\aa.pdf"; 

title justify=center "t1"; 
proc sgplot 
... 
run; 

title justify=center "t2"; 
proc sgplot 
... 
run; 

ods pdf close; 

Я не понимаю, почему, когда я помещаю два графика на одну страницу, второй заголовок отсутствует в выходном файле pdf.

Если я поместил два графика на две страницы, появится второй заголовок. Но мне они нужны на одной странице.

Было бы намного лучше, если бы можно было оставить несколько пустых строк между двумя графиками.

Идеальный выход:

title1 
graph1 

title2 
graph2 

То, что я сделал:

title1 
graph1 
graph2 

Answer 1

У Реэзы была та же проблема некоторое время назад на сообществах сас. Синтия (SAS) объяснила, что заголовки попадают в начало страницы. Поскольку вы вынуждаете его использовать то же самое, удаляя разрыв страницы, второй заголовок не отображается. Один из способов - использовать текст ODS.

См. Код ниже, он использует два новых оператора по сравнению с вашим кодом. Первая строка задает символ возврата, который будет использоваться во второй строке для установки текстового блока, который будет использоваться вместо заголовка.

ods escapechar = '^';

ods pdf text = "^ S = {just = c} Это мое временное название";

options orientation=portrait; 
GOPTIONS device=ACTXIMG; 
ods escapechar='^'; 
options nocenter nodate nonumber; 
ods graphics/noborder width= 1200 height=360 scale; 
ods pdf startpage=never file="/home/healthcarep/work/floss/aa.pdf"; 
title justify=center "t1"; 

proc sgplot data=sashelp.class; 
    scatter x=height y=weight/group=sex; 
run; 

title justify=center "t2"; 
ods pdf text="^S={just=c} This is my interim title"; 

proc sgplot data=sashelp.class; 
    scatter x=height y=weight/group=sex; 
run; 

ods pdf close; 

Это временное решение, но это может MEED ваши потребности.

С уважением, Vasilij

Answer 2

Предлагайте добавив опцию GTITLE к вашему ODS заявление. Это должно означать, что SAS помещает заголовок в графическое изображение, а не заголовок страницы. Я думаю, что GTITLE был добавлен в ODS PDF в версии 9.3.

ods pdf file="d:\junk\want.pdf" startpage=never gtitle; 

title1 "Some Title AAA"; 
proc sgplot data=sashelp.class; 
    scatter x=height y=weight; 
run; 
title1; 

title1 "Some Title BBB"; 
proc sgplot data=sashelp.class; 
    scatter x=height y=weight; 
run; 
title1; 
ods pdf close;