Как использовать SequenceRunner с FlexUnit 4

Question

В FlexUnit wiki Я читал о очень интересном SequenceRunner, который был внесен людьми Fluint. Теперь я пытаюсь запустить тест, который очень похож на пример, однако при выполнении прогона() метод экземпляра SequenceRunner, я получаю это исключение:

Cannot add asynchronous functionality to methods defined by Test,Before or After that are not marked async 
Error: Cannot add asynchronous functionality to methods defined by Test,Before or After that are not marked async 
    at org.flexunit.async::AsyncLocator$/getCallableForTest()[C:\Users\dmoor e\Documents\_Production\Flex Unit 4\GIT\FlexUnit4\src\org\flexunit\async\AsyncLocator.as:82] 
    at org.fluint.sequence::SequenceWaiter/setupListeners()[C:\Users\dmoore\ Documents\_Production\Flex Unit 4\GIT\FlexUnit4\src\org\fluint\sequence\SequenceWaiter.as:100] 
    at org.fluint.sequence::SequenceRunner/continueSequence()[C:\Users\dmoor e\Documents\_Production\Flex Unit 4\GIT\FlexUnit4\src\org\fluint\sequence\SequenceRunner.as:177] 
    at org.fluint.sequence::SequenceRunner/run()[C:\Users\dmoore\Documents\_ Production\Flex Unit 4\GIT\FlexUnit4\src\org\fluint\sequence\SequenceRunner.as:124] 

Кто-нибудь использовал SequenceRunner с FlexUnit 4 уже , Антенна [Test (async)] уже присутствует.

Answer 1

Благодаря Майклу Лабриоле, который ответил на мой вопрос в Adobe Forum, я наконец смог его запустить. Обратите внимание, что документация SequenceRunner in the Wiki устарела и частично ошибочна.

1. Не наследуйте ни один класс TestCase.
2. Пропустите асинхронный вызов для CREATION_COMPLETE в setUp. Вместо добавления SequenceWaiter в тесте, что ждет за CREATION_COMPLETE события компонента
3. Тест должен быть помечен как асинхронный тест, поэтому добавьте [Test(async)] метаданные для проверки случаев, которые используют SequenceRunner.

Answer 2

Вот полный, очень простой пример тестового класса.

package test 
{ 
    import flash.events.Event; 

    import org.flexunit.asserts.assertEquals; 

    import org.fluint.sequence.SequenceRunner; 
    import org.fluint.sequence.SequenceWaiter; 

    public class test_case 
    { 
     [Test(async)] 
     public function test_function():void 
     { 
      var counter:Object = { count: 0} 
      var sr:SequenceRunner = new SequenceRunner(this); 
      sr.addStep(new SequenceWaiter(new TestWaiterTarget(counter), "myEvent", 50000)); 
      sr.addStep(new SequenceWaiter(new TestWaiterTarget(counter), "myEvent", 5000)) 
      sr.addAssertHandler(test_function_handler, counter); 
      sr.run(); 
     } 

     private function test_function_handler(event:Event, passthroughData:*):void 
     { 
      assertEquals(passthroughData.count, 2); 
     } 
    } 
} 

import flash.events.Event; 
import flash.events.EventDispatcher; 
import flash.events.TimerEvent; 
import flash.utils.Timer; 

class TestWaiterTarget extends EventDispatcher 
{ 
    var timer:Timer = new Timer(250, 1); 

    private var _counter:Object; 

    public function TestWaiterTarget(counter) 
    { 
     _counter = counter; 
     timer.addEventListener(TimerEvent.TIMER_COMPLETE, timer_timerCompleteHandler); 
     timer.start(); 
    } 

    private function timer_timerCompleteHandler(event:TimerEvent):void 
    { 
     _counter.count++; 
     dispatchEvent(new Event("myEvent")); 
    } 
}