XSLT-преобразования разделенных запятой XML элемент

Question

У меня есть XML-документ, как этот пример (с пробелами, как показано)

<block> 
<Text>FirstName: Bob, LastName: Smith, PhoneNumber: 12345</Text> 
<block> 

и хотел бы преобразовать в XSLT, так что XML становится

<block> 
<Text> 
    <FirstName>Bob</FirstName> 
    <LastName>Smith</LastName> 
    <PhoneNumber>12345</Phonenumber> 
</Text> 
<block> 

Любая помощь очень ценится, Большое спасибо !.

Answer 1

В таблице стилей ниже используется именованный рекурсивный шаблон в качестве токенизатора для текстового содержимого. Он читает первый текст перед запятой и создает элемент со строкой перед точкой с запятой, содержащую строку после точки с запятой. Затем он снова вызывает метод со строкой после запятой, пока не будет найдено больше запятых и будет создан последний элемент.

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"> 

    <xsl:template match="block"> 
     <xsl:copy> 
      <xsl:apply-templates /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="Text"> 
     <xsl:copy> 
      <xsl:call-template name="tokenize"> 
       <xsl:with-param name="text" select="."/> 
       <xsl:with-param name="separator" select="','" /> 
      </xsl:call-template> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template name="tokenize"> 
     <xsl:param name="text"/> 
     <xsl:param name="separator"/> 
     <xsl:choose> 
      <xsl:when test="not(contains($text, $separator))"> 
       <xsl:element name="{substring-before($text, ':')}"> 
        <xsl:value-of select="substring-after($text, ': ')"/> 
       </xsl:element> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:element name="{substring-before($text, ':')}"> 
        <xsl:value-of select="substring-before(substring-after($text, ': '), $separator)"/> 
       </xsl:element> 
       <xsl:call-template name="tokenize"> 
        <xsl:with-param name="text" select="substring-after($text, concat($separator, ' '))"/> 
        <xsl:with-param name="separator" select="','" /> 
       </xsl:call-template> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 2

Вы можете использовать эту таблицу стилей:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" indent="yes"/> 

<xsl:template match="node() | @*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node() | @*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="Text"> 
    <xsl:copy> 
     <xsl:for-each select="tokenize(text(), ',')"> 
      <xsl:element name="{normalize-space(tokenize(.,':')[1])}"> 
       <xsl:value-of select="normalize-space(tokenize(.,':')[2])"/> 
      </xsl:element> 
     </xsl:for-each> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet> 

Answer 3

XSLT 2.0 решение, которое использует функцию tokenize() разделить на ',' и создания желаемого содержания:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 
    <xsl:output indent="yes"/> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="Text"> 
     <xsl:copy> 
      <xsl:for-each select="tokenize(., ',\s?')"> 
       <xsl:element name="{substring-before(current(), ': ')}"> 
        <xsl:value-of select="substring-after(., ': ')"/> 
       </xsl:element> 
      </xsl:for-each> 
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

XSLT 1.0 решения, которое использует рекурсивный шаблон:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output indent="yes"/> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="Text"> 
     <xsl:copy> 
      <xsl:call-template name="split"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template name="split"> 
     <xsl:param name="val" select="."/> 
     <xsl:param name="delimiter" select="','"/> 
     <xsl:if test="string-length($val) and contains($val, ':')"> 
      <xsl:variable name="item" select="substring-before(concat($val, $delimiter), $delimiter)"/> 
      <xsl:element name="{substring-before($item, ': ')}"> 
       <xsl:value-of select="substring-after($item, ': ')"/> 
      </xsl:element> 
      <xsl:call-template name="split"> 
       <xsl:with-param name="val" select="substring-after($val, $delimiter)"/> 
       <xsl:with-param name="delimiter" select="$delimiter"/> 
      </xsl:call-template> 
     </xsl:if> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 4

Вот один, который использует XSLT 2,0

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="2.0"> 

    <xsl:output omit-xml-declaration="yes"/> 

    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="Text"> 
     <xsl:copy> 
      <xsl:for-each select="tokenize(., ', ')"> 
       <xsl:element name="{substring-before(., ':')}"> 
        <xsl:value-of select="substring-after(., ': ')"/> 
       </xsl:element> 
      </xsl:for-each> 
      </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

применительно к вашей входной XML, выход:

<block> 
    <Text> 
     <FirstName>Bob</FirstName> 
     <LastName>Smith</LastName> 
     <PhoneNumber>12345</PhoneNumber> 
    </Text> 
</block>