Преобразование 2-кортеж 3-кортеж Haskell

Question

Поэтому у меня есть список кортежей:

[(1,2),(2,3),(3,4)] 

, например. И я выполняю расчет по его элементам. Результат этого должен быть присоединен к этому кортежу, но я не знаю, как это сделать.

[(1,2,103),(2,3,809),(3,4,2034)] 

- формат, о котором я думаю.

Answer 1

Предполагая, что у вас есть функция вычисления, как:

calculate :: Int -> Int -> Int 

вы можете сделать

calculateAll :: [(Int, Int)] -> [(Int, Int, Int)] 
calculateAll = map (\(x, y) -> (x, y, calculate x y)) 

или более общо:

calculateAllWith :: (a -> b -> c) -> [(a, b)] -> [(a, b, c)] 
calculateAllWith f = map (\(x, y) -> (x, y, f x y)) 

Answer 2

Используйте map функцию:

calc :: (Int, Int) -> (Int, Int, Int) 
calc = error "Implement me" 

calcList :: [(Int, Int)] -> [(Int, Int, Int)] 
calcList = map calc 

Answer 3

Довольно простое решение:

import Control.Applicative ((<*>)) 

mapResultOn3rd :: (a -> b -> c) -> [(a,b)] -> [(a,b,c)] 
mapResultOn3rd f = map (uncurry (,,) <*> uncurry f) 

Например, в GHCI:

>>> mapResultOn3rd (:) [(1,[2]), (3,[4,5])] 
[(1,[2],[1,2]),(3,[4,5],[3,4,5])] 

Answer 4

Вы также можете использовать список понимание в GHCi:

Prelude> let list = [(1,2),(2,3),(3,4)] 
Prelude> [(x,y,x*y) | (x,y) <- list] 
[(1,2,2),(2,3,6),(3,4,12)] 

http://www.haskell.org/haskellwiki/List_comprehension

Или используйте Список как монада:

Prelude> do (x,y) <- list; return (x,y,x*y) 
[(1,2,2),(2,3,6),(3,4,12)] 

Но я предпочитаю список понимание :-)