Как запустить макрос Excel VBA непрерывно?

Question

Я пытаюсь написать макрос для автоматической сортировки таблицы в Excel при изменении любого значения в таблице.
Это мой код VBA

Sub Macro3(ByVal target As Range) 
    ActiveWorkbook.Worksheets("Sheet1").ListObjects("Table4").sort.SortFields.Clear 
    ActiveWorkbook.Worksheets("Sheet1").ListObjects("Table4").sort.SortFields.Add _ 
     Key:=Range("Table4[Pts]"), SortOn:=xlSortOnValues, Order:=xlDescending, _ 
     DataOption:=xlSortNormal 
    ActiveWorkbook.Worksheets("Sheet1").ListObjects("Table4").sort.SortFields.Add _ 
     Key:=Range("Table4[GD]"), SortOn:=xlSortOnValues, Order:=xlDescending, _ 
     DataOption:=xlSortNormal 
    ActiveWorkbook.Worksheets("Sheet1").ListObjects("Table4").sort.SortFields.Add _ 
     Key:=Range("Table4[GF]"), SortOn:=xlSortOnValues, Order:=xlDescending, _ 
     DataOption:=xlSortNormal 
    With ActiveWorkbook.Worksheets("Sheet1").ListObjects("Table4").sort 
     .Header = xlYes 
     .MatchCase = True 
     .Orientation = xlTopToBottom 
     .SortMethod = xlPinYin 
     .Apply 
    End With 
End Sub 

Sub sort() 
    Dim target As Range 
    Set target = Range("Table4") 
    Call Macro3(target) 
End Sub 

Что я должен сделать, чтобы этот макрос работает непрерывно каждый раз значение в изменении таблицы?

Answer 1

A Worksheet_Change Событие макроса не будет инициироваться, если значения ячейки изменены из-за изменения формулы ячейки из изменения на другом листе. Для этого вам нужно записать событие Worksheet_Calculate.

Это не код модуля. Он принадлежит кодовой странице Sheet1. Щелкните правой кнопкой мыши вкладку Sheet1 внизу вашей книги и выберите «Просмотреть код». Когда откроется VBE, вставьте следующее в панель под названием что-то вроде Book1 - Sheet1 (Code).

Private Sub Worksheet_Calculate() 
    On Error Goto bm_Safe_Exit 
    Application.EnableEvents = False 
    With ListObjects("Table4").Sort 
     With .SortFields 
      .Clear 
      .Add Key:=Range("Table4[[#All],[Pts]]"), Order:=xlDescending 
      .Add Key:=Range("Table4[[#All],[GD]]"), Order:=xlDescending 
      .Add Key:=Range("Table4[[#All],[GF]]"), Order:=xlDescending 
     End With 
     .Header = xlYes 
     .Apply 
    End With 
bm_Safe_Exit: 
    Application.EnableEvents = True 
End Sub 

Нажмите Alt + Q, чтобы вернуться на рабочий лист. Если формулы пересчитываются, данные в Таблице 4 будут применены. Мониторинг событий временно приостанавливается, так что акт сортировки не вызывает другого события вычисления.

Answer 2

Чтобы выполнить макрос каждый раз при изменении ячейки в таблице/диапазоне, вы можете использовать events, который вы вводите в код для листа.

В вашем случае, вы, вероятно, хотите что-то вроде:

Private Sub Worksheet_Change(ByVal Target As Range) 
    If Not Intersect(Target, range_of_table) Is Nothing Then 
    Call sort 
    End If 
End Sub 

Где range_of_table является диапазон таблицы, которую вы создали.