Фильтр AdoDB при объединенных столбцах

Question

Итак, у меня есть AdoTable, связанный с базой данных (mdb) и DataSource с ее использованием. Этот DataSource используется DBGrid ...

Я попытался отфильтровать AdoTable на основе пользовательского ввода. Есть 3 важных столбца: имя, фамилия и идентификатор. Я придумал что-то вроде этого, как временное решение:

AdoTable.filter:='surname like ' + 
     QuotedStr('%'+edit1.text+'%')+' or name like ' + 
     QuotedStr('%'+edit1.text+'%')+' or ID like ' + 
     QuotedStr('%'+edit1.text+'%'); 
AdoTable.filtered:=true; 

Это делает работу, но это не делает именно то, что я хотел бы это сделать ... (при поиске имени и Фамилии не будет найти что-либо, поскольку оно выглядит только в одном столбце). Так позже я изменил мой код в этом:

AdoTable.filter:='surname & " " & name like ' + 
     QuotedStr('%'+edit1.text+'%')+' or name & " " & surname like ' + 
     QuotedStr('%'+edit1.text+'%')+' or ID like ' + 
     QuotedStr('%'+edit1.text+'%'); 
AdoTable.filtered:=true; 

Теперь это будет делать exacly, что я хочу, чтобы это сделать, но это вызывает исключение (EOleException: аргументы имеют неправильный тип, находятся вне допустимого диапазона, или находятся в конфликте друг с другом). Это довольно удивляет меня, поскольку я думал, что он должен вести себя как предложение where в команде sql (и он отлично работает как команда).

Я попытался заменить '&' на '+'. Я мог бы разделить текст ввода, но я не хочу этого делать (он будет работать плохо, если у вас будут такие имена, как Робин ван Перси, Ахмад ибн Ханбал и т. Д.)

В качестве альтернативы я мог бы переписать всю программу использовать запросы вместо таблиц, но я действительно не хочу этого делать (это также означало бы, что я получаю новый пользователь recordSet. EVERYTIME изменит edit1.text вместо простой фильтрации).

Любые идеи?

редактировать: так команда, которая работает выглядит следующим образом

select * from person where surname & " " & name like '%John Smith%' or name & " " & surname like '%John Smith%' or ID like '%John Smith%' 

фильтр выглядит следующим образом (и это вызывает исключение)

surname & " " & name like '%John Smith%' or name & " " & surname like '%John Smith%' or ID like '%John Smith%' 

Обратите внимание, что может быть «кп Смит» вместо «John Smith», так что он найдет также «Kann Smithers» и т. Д.

Answer 1

Код ниже отлично работает с помощью AdoTable, который обращается к employee ta в базе данных Delphi dbdemos.mdb. Мой AdoConnection использует драйвер Microsoft Jet 4.0 OLE DB.

procedure TForm1.Button1Click(Sender: TObject); 
var 
    FilterExpr : String; 
begin 
    AdoTable1.Filtered := not AdoTable1.Filtered; 
    if AdoTable1.Filtered then begin 
    FilterExpr := 'FirstName like ' + QuotedStr('%' + Edit1.Text + '%') + ' or LastName like ' + QuotedStr('%' + Edit1.Text + '%'); 
    AdoTable1.Filter := FilterExpr; 
    end; 
end; 

Я думаю, что ваша ошибка, вероятно, заключается в использовании указанного синтаксиса для конкретного доступа. Вы получаете доступ к таблице через уровень ADO и что AFAIK ожидает того же синтаксиса, который вы бы использовали, например. для серверного сервера Sql.

Из вашего комментария кажется, что вы хотите прикрыть случай, когда пользователь вводит в ваш Edit1.Text фрагмент первого имени, за которым следует пробел, за которым следует фрагмент или фамилия. Далее будет сделать:

procedure TForm1.Button1Click(Sender: TObject); 
var 
    FilterExpr : String; 
    P : Integer; 
    S1, 
    S2 : String; 
begin 
    AdoTable1.Filtered := not AdoTable1.Filtered; 
    if AdoTable1.Filtered then begin 
    P := Pos(' ', Trim(Edit1.Text)); 
    if P > 0 then begin 
     S1 := Copy(Trim(Edit1.Text), 1, P - 1); 
     S2 := Copy(Trim(Edit1.Text), P + 1, MaxInt); 
     FilterExpr := '(FirstName like ' + QuotedStr('%' + S1 + '%') + ')'; 
     FilterExpr := FilterExpr + ' or (LastName like ' + QuotedStr('%' + S2 + '%') + ')'; 
    end 
    else 
     FilterExpr := 'FirstName like ' + QuotedStr('%' + Edit1.Text + '%') + ' or LastName like ' + QuotedStr('%' + Edit1.Text + '%'); 
    AdoTable1.Filter := FilterExpr; 
    end; 
end; 

Update: Если вы хотите, чтобы позволить пользователю ввести что-то вроде

HN Smith

, то вы можете использовать событие FilterRecord как это вместо код выше.

procedure TForm1.ADOTable1FilterRecord(DataSet: TDataSet; var Accept: Boolean); 
var 
    S : String; 
begin 
    S := LowerCase(DataSet.FieldByName('FirstName').AsString + ' ' + DataSet.FieldByName('LastName').AsString); 
    Accept := Pos(LowerCase(Edit1.Text), S) > 0; 
end; 

Преобразование в строчные, очевидно, игнорировать любой капитализации пользователь мог бы использовать.

Answer 2

Я нашел это: Using LIKE statement for filtering и использовал принятый ответ, и он работает нормально. (Не удалось найти его раньше, как вопрос весьма отличается)

В таблице фильтра:

procedure TDataModule1.ADOTableFilterRecord(DataSet: TDataSet; 
    var Accept: Boolean); 
var 
    nameSurname :string; 
    surnameName :string; 
begin 
    nameSurname:= DataSet.FieldByName('name').AsString+' '+DataSet.FieldByName('surname').AsString; 
    surnameName:= DataSet.FieldByName('surname').AsString+' '+DataSet.FieldByName('name').AsString; 

    if assigned(MainForm) then 
    Accept := (Pos(MainForm.edit1.Text, nameSurname) > 0) 
    or (Pos(MainForm.edit1.Text, surnameName) > 0) 
    or (Pos(MainForm.edit1.Text, DataSet.FieldByName('ID').AsString) > 0); 
end; 

на изменение редактирования:

procedure TMainForm.edit1Change(Sender: TObject); 
begin 
    DataModule1.AdoTable.Filtered:=false; 
    if edit1.Text<>'' then 
     DataModule1.AdoTable.Filtered:=True; 
end; 

Спасибо за ваше время ... Я оставлю это здесь .. Я думаю, что в конце концов кому-то это понадобится