Почему этот TStreamAdapter не выпущен?

Question

Сравните эти два фрагмента:

(d as IPersistStream).Save(
    TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmCreate),soOwned),true); 
(d as IPersistStream).Load(
    TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmOpenRead),soOwned)); 

Это терпит неудачу на втором TFileStream.Create, потому что первый не разрушается. Это странно, так как параметр имеет единственную ссылку, я думал, что он будет уничтожен при закрытии вызова Save. Поэтому я пробовал это:

var 
    x:IStream; 
begin 
    x:=TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmCreate),soOwned); 
    (d as IPersistStream).Save(x,true); 
    x:=nil; 
    x:=TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmOpenRead),soOwned); 
    (d as IPersistStream).Load(x); 
    x:=nil; 

Который работает нормально. (Но снова сработает без x:=nil;) Так что не волнуйтесь о d, это is a IPersistStream и ведет себя правильно. Почему для принудительного вызова _Release требуется явное назначение nil? Это проблема с Delphi 7? Это из-за переключателя компоновщика/компилятора?

Answer 1

Вот декларация IPersistStream.Save:

function Save(const stm: IStream; fClearDirty: BOOL): HResult; stdcall; 

Ключевым моментом является то, что параметр потока передается как const. Это означает, что функция Save не принимает ссылки на интерфейс IStream. Его счетчик ссылок не увеличивается и не уменьшается. И так как это не происходит, оно никогда не разрушается.

Путь к работе заключается в том, чтобы убедиться, что что-то содержит ссылку на интерфейс. Это то, что вы демонстрируете во втором примере.

Причина, по которой вам нужно задание nil вниз в порядке, в котором выполняется этот код:

x := TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmOpenRead),soOwned 
); 

Это происходит в следующем порядке:

1. TFileStream.Create.
2. TStreamAdapter.Create.
3. x._Release очистить старую ссылку.
4. Отправьте ссылку на новый IStream.

И это явно не в порядке. Перед вызовом TFileStream.Create необходимо очистить x.

---

По словам бывшего инженера компилятора Embarcadero, Барри Келли, the issue regarding the interface passed to a const parameter is a bug. Это никогда не было исправлено, и я отказался от надежды на это.

Мой SSCCE показать вопрос здесь:

program SO22846335; 

{$APPTYPE CONSOLE} 

type 
    TMyInterfaceObject = class(TObject, IInterface) 
    FRefCount: Integer; 
    FName: string; 
    function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall; 
    function _AddRef: Integer; stdcall; 
    function _Release: Integer; stdcall; 
    constructor Create(const Name: string); 
    destructor Destroy; override; 
    end; 

constructor TMyInterfaceObject.Create(const Name: string); 
begin 
    inherited Create; 
    FName := Name; 
    Writeln(FName + ' created'); 
end; 

destructor TMyInterfaceObject.Destroy; 
begin 
    Writeln(FName + ' destroyed'); 
    inherited; 
end; 

function TMyInterfaceObject.QueryInterface(const IID: TGUID; out Obj): HResult; 
begin 
    Result := E_NOINTERFACE; 
end; 

function TMyInterfaceObject._AddRef: Integer; 
begin 
    Writeln(FName + ' _AddRef'); 
    Result := AtomicIncrement(FRefCount); 
end; 

function TMyInterfaceObject._Release: Integer; 
begin 
    Writeln(FName + ' _Release'); 
    Result := AtomicDecrement(FRefCount); 
    if Result = 0 then 
    Destroy; 
end; 

procedure Foo(const Intf: IInterface); 
begin 
    Writeln('Foo'); 
end; 

procedure Bar(Intf: IInterface); 
begin 
    Writeln('Bar'); 
end; 

begin 
    Foo(TMyInterfaceObject.Create('Instance1')); 
    Bar(TMyInterfaceObject.Create('Instance2')); 
    Readln; 
end. 

Выход

 
Instance1 created 
Foo 
Instance2 created 
Instance2 _AddRef 
Bar 
Instance2 _Release 
Instance2 destroyed