Перебор файл, пропуская пустые строки

Question

У меня есть файл в следующем формате

value value 17 -1 1234 4567 value id1 
value value 17 -1 2345 4580 value id1 
value value 17 -1 2344 4654 value id1 

value value 1 1 1234 4567 value id2 
value value 1 1 3445 3455 value id2 

value value 1 1 2341 2345 value id3 
value value 1 1 1245 4567 value id3 
value value 1 1 3234 5634 value id3 
value value 1 1 3412 4512 value id3 

Я хочу, чтобы получить следующую информацию для каждой группы линий между заготовками строк:

для, например, для id1:

17 -1 1234 4654 id1 

для id2:

1 1 1234 3455 id2 

i.e для каждого id (последний столбец) Я хотел бы получить 5-й столбец первой строки в этой группе и 6-й столбец последней строки в этой группе (строки сгруппированы по идентификаторам).

Answer 1

Нечто подобное может сделать работу для вас

$ awk '/^$/{print col3, col4, col5, col6, idval; next} $8 != idval{idval = $8; col3=$3; col4=$4; col5=$5} {col6=$6} END{print col3, col4, col5, col6, idval}' input 
17 -1 1234 4654 id1 
1 1 1234 3455 id2 

Answer 2

С GNU awk

awk -vRS= -vFS='\n' '{split($1, a, /[[:blank:]]+/); 
split($NF, b, /[[:blank:]]+/); 
print a[3], a[4], a[5], b[6], a[8]}' file 
17 -1 1234 4654 id1 
1 1 1234 3455 id2 
1 1 2341 4512 id3 

Answer 3

Вот еще awk

awk -vRS= '{print $3,$4,$5,$(NF-2),$8}' file 
17 -1 1234 4654 id1 
1 1 1234 3455 id2 
1 1 2341 4512 id3 

Этот разрыв каждый блок на одну запись, то поле печати 3,4,5 третьего и 8