Как выбрать некоторые элементы из массива Perl?

Question

Я хочу найти все элементы в массиве, которые имеют одинаковый стартовый набор символов как элемент в другом массиве. Чтобы уточнить:

@array = ("1a","9","3c"); 
@temp =("1","2","3"); 

Я хочу напечатать только 1a и 3c. Когда я пытаюсь использовать следующую программу она выводит все элементы массива вместо двух я хочу:

foreach $word (@temp) 
{ 
    if(grep /^$word/ , @array) 
    { 
     print $_; 
    } 
} 

будут оценены Любые идеи.

Answer 1

Этот ответ будет делать то, что ОП хочет, а также предотвратить любые дубликаты из печати на экране через использование хэш-поиска.

#!/usr/bin/perl 

use strict; 
use warnings; 

my @array = ("1a","9","3c","3c"); 
my @temp =("1","2","3"); 

my %dups_hash; 

for my $w (@temp) { 
    my ($match) = grep /^$w/, @array; 

    # Need to check if $match is defined before doing the hash lookup. 
    # This suppresses error messages for uninitialized values; if defined($match) is 
    # false, we short circuit and continue in the loop. 
    if(defined($match) && !defined($dups_hash{$match})) { 
     print $match; 
    } 
} 

Answer 2

Если вы хотите, чтобы соответствовать элементы попарно, вы можете сделать это следующим образом:

for my $i (0..$#array) { 
    print $array[$i], "\n" if $array[$i] =~ /^$temp[$i]/ 
} 

В противном случае вы можете использовать Grep:

for my $i (0..$#array) { 
    print "$array[$i]\n" if grep /^$temp[$i]/, @array; 
} 

Answer 3

Когда я пытаюсь использовать следующую программа распечатывает все элементы в массиве вместо двух I .

Нет, это не так. Как написано, оно ничего не печатает. При строгом включении он печатает «Глобальный символ» $ temp «требует явного пакета».

Исправление этой очевидной опечатки и включение предупреждений, она печатает «Использование неинициализированного значения $ _ в печати» дважды.

Пожалуйста, не тратьте свое время, показывая нам код, который либо не компилируется, не делает того, что вы говорите. Не перепечатывайте код на этот сайт - вырезайте и вставьте фактический код, который вы используете.

Решение вашей проблемы будет что-то вроде:

#!/usr/bin/perl 

use strict; 
use warnings; 

my @array = ("1a","9","3c"); 
my @temp =("1","2","3"); 

foreach my $word (@temp) { 
    print grep /^$word/ , @array; 
} 

Но есть, вероятно, более эффективные способы сделать это.

Answer 4

map { print "$_\n" } grep { my $a = $_; grep {$a =~ /^$_/} @temp } @array 

В основном, внешний grep выбирает элементы, для которых один или более из элементов в @temp соответствует внутреннему regex--, которое он выбирает все элементы, которые начинаются с одной (или более) элементов @temp.

Answer 5

Чтобы избежать пустых строк, если возвращение Grep пустой список:

#!/usr/bin/perl 
use strict; 
use warnings; 
use 5.10.1; 

my @array = qw(1a 9 3c 1g); 
my @temp =(1, 2, 3); 
foreach my $word(@temp) { 
    my @l = grep{/^$word/}@array; 
    say "@l" if @l; 
} 

Выход:

1a 1g 
3c 

Answer 6

Для такого рода проблем фокус в том, чтобы не сканировать массив больше, чем вам нужно. Я думаю, что Кнут написал об этом целую книгу. :) Часто мы застряли в этих ситуациях, потому что мы слишком пристально следим за тем, что мы пробовали в первую очередь.

Вы можете построить регулярное выражение, из всех моделей, которые вы хотите найти, то сканирование массива сразу:

use Regexp::Assemble; 

my @array = qw(1a 9 3c); 
my @temp = qw(1 2 3); 

my $ra = Regexp::Assemble->new; 
$ra->add(@temp); 

my $pattern = $ra->re; 
print "pattern is [$pattern]\n"; 

print join ' ', grep /\A$pattern/ , @array; 

Такого рода вещи работает, когда вы не заботитесь, какая часть рисунка если он совпадает.