пакетный файл удалить все, кроме новейших 10 файлов

Question

У меня есть следующие в пакетном файле:

:REMOLDFILES 
ECHO Removing files older than 14 days. >>%LOGFILE% 
cd /d %BKUPDIR% 
FOR /f "skip=14 delims=" %%A IN ('DIR /a:-d /b /o:-d /t:c %1*.zip ^2^>nul') DO IF EXIST "%%~fA" ECHO "%%~fA" >>%LOGFILE% 
FOR /f "skip=14 delims=" %%A IN ('DIR /a:-d /b /o:-d /t:c %1*.zip ^2^>nul') DO IF EXIST "%%~fA" DEL "%%~fA" >>%LOGFILE% 
FOR /f "skip=14 delims=" %%A IN ('DIR /a:-d /b /o:-d /t:c %1*.log ^2^>nul') DO IF EXIST "%%~fA" ECHO "%%~fA" >>%LOGFILE% 
FOR /f "skip=14 delims=" %%A IN ('DIR /a:-d /b /o:-d /t:c %1*.log ^2^>nul') DO IF EXIST "%%~fA" DEL "%%~fA" >>%LOGFILE% 
IF [%3]==[Y] GOTO SECONDBACKUPDIR 
IF [%3]==[y] GOTO SECONDBACKUPDIR 
GOTO END 

Проблема я столкнулся и в том, что резервная копия была не работает в течение нескольких недель, и в конечном итоге удаление все мои резервные копии, так как им было более 2 недель.

Что мне нужно, чтобы сохранить последние 10 последних резервных копий.

У кого-нибудь есть идея, как я это сделаю? Я не писал это один раз, так как я не знаком с пакетными файлами.

Answer 1

Вы можете использовать FOR /F SKIP игнорировать последние 10 наиболее недавно измененные записи после сортировки по дате последнего изменения:

for /f "skip=10 eol=: delims=" %%F in ('dir /b /o-d *.zip') do @del "%%F" 

Answer 2

Вы можете получить список файлов в обратном порядке по дате изменения с помощью команды DIR. Затем вы просто скажете свой цикл FOR, чтобы пропустить первые 10 (примечание ваш почтовый индекс показывает 14, но вы запрашиваете 10) записей, поэтому все обрабатываемое будет удалено.

REM Update to 14 if needed. 
SET Keep=10 
FOR /F "usebackq tokens=* skip=%Keep% delims=" %%A IN (`DIR *.zip /B /O:-D /A:-D`) DO DEL "%%A">>%LOGFILE% 

Поскольку вы не знакомы с партией, вы можете проверить эту команду (чтобы увидеть, что будет удалено, а не на самом деле удалить его), заменив DEL с ECHO.

---

Редактировать

Поскольку вы также обработки лог-файлов, поэтому не просто удалять их в одном цикле?

REM Update to 14 if needed. 
SET Keep=10 
FOR /F "usebackq tokens=* skip=%Keep% delims=" %%A IN (`DIR *.zip /B /O:-D /A:-D`) DO (
    ECHO Processing: %%~nA 
    REM Delete ZIP file. 
    DEL "%%A" 
    REM Delete LOG file. 
    DEL "%%~nA.log" 
)>>%LOGFILE%