Как выбрать содержимое текстового поля после его активации?

Question

У меня есть эта простая Userform, где у меня есть только TextBox1 и TextBox2. Я ввожу в них текст. Предположим, что фокус включен (курсор находится) TextBox2. Когда я нажимаю на TextBox1, я хочу, чтобы весь текст в этом элементе управления был выделен (выбран). Таким образом, я использую этот код:

Private Sub TextBox1_Enter() 
    With TextBox1 
     .SetFocus 
     .SelStart = 0 
     .SelLength = Len(.Text) 
    End With 
    MsgBox "enter event was fired" 
End Sub 

Там является MsgBox в конце, который загружается, это означает, что произведения событий. Однако текст не подсвечивается. Как это исправить?

Я использую Enter событие и не хочу использовать MouseDown события, потому что мне нужно код, чтобы работать, когда TextBox1 активируется программно, так что я чувствую Enter событие, чтобы быть лучшим выбором, так как он уволен в обоих случаях! Еще один недостаток события MouseDown: когда я нажимаю второй раз на TextBox1, я бы не ожидал, что весь текст будет выделен больше, потому что фокус был установлен на первом клике, и он не изменился после того, как я нажал на тот же контроль во второй раз; поэтому в этом случае я бы хотел, чтобы курсор работал нормально (чтобы не помечать текст).

Update
Когда я один раз нажать на TextBox1, я ожидаю получить этот результат:
Если нажата снова, подсветка будет удалена, и курсор будет помещен в том месте, где это было щелкнул.

Answer 1

не может быть более простым, чем это я думаю ...

Private Sub TextBox1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, _ 
ByVal X As Single, ByVal Y As Single) 
    With TextBox1 
     .SelStart = 0 
     .SelLength = Len(.Text) 
    End With 
End Sub 

ли вы нажмите на текстовое поле или вкладку в него, он будет делать то, что вы хотите. Чтобы отменить выбор текста, используйте клавиши со стрелками.

Объяснение

Если вы отлаживать код, который вы увидите, что даже если вы сказали .SetFocus, акцент делается не на TextBox. .SetFocus не работает в TextBox1_Enter(), и вам нужно сосредоточиться на остальной части кода для работы. И, следовательно, моя альтернатива ...

Alternative

Вы можете также как этот вариант :) Это преодолевает ограничение с помощью мыши в TextBox

Dim boolEnter As Boolean 

Private Sub TextBox1_Enter() 
    boolEnter = True 
End Sub 

Private Sub TextBox1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, _ 
ByVal X As Single, ByVal Y As Single) 
    If boolEnter = True Then 
     With TextBox1 
      .SelStart = 0 
      .SelLength = Len(.Text) 
     End With 
     boolEnter = False 
    End If 
End Sub 

Answer 2

использование этого

Private Sub TextBox1_Enter() 
    With TextBox2 
     .ForeColor = vbBlack 
     .Font.Bold = False 
    End With 
    With TextBox1 
     .ForeColor = vbRed 
     .Font.Bold = True 
    End With 
End Sub 

Private Sub TextBox2_Enter() 
    With TextBox1 
     .ForeColor = vbBlack 
     .Font.Bold = False 
    End With 
    With TextBox2 
     .ForeColor = vbRed 
     .Font.Bold = True 
    End With 
End Sub 

Answer 3

Пфф, мне потребовалось некоторое время. На самом деле, ваш код работает, но он выделяет текст до того, как произойдет событие клика. Таким образом, вы щелкаете в ящике, мгновенно переопределяя выбор, созданный кодом. я использовал задержанный выбор, и он работает, хотя это немного противно ...

Код для текстовых полей:

Private Sub TextBox1_Enter() 
    Application.OnTime Now + TimeValue("00:00:01"), "module1.SelectText1" 
End Sub 

Private Sub TextBox2_Enter() 
    Application.OnTime Now, "module1.SelectText2" 
End Sub 

Обратите внимание, что он работает даже withouth в {+ TimeValue (» 00:00:01 ")}, но это теоретически может помешать ему работать время от времени. Хм, подумав, просто оставьте это. Я сомневаюсь, что это вызовет проблему.

Теперь код в Module1:

Sub SelectText1() 
    UserForm1.TextBox1.SelStart = 0 
    UserForm1.TextBox1.SelLength = Len(UserForm1.TextBox1.Text) 
End Sub 

Sub SelectText2() 
    UserForm1.TextBox2.SelStart = 0 
    UserForm1.TextBox2.SelLength = Len(UserForm1.TextBox2.Text) 
End Sub 

Надеется, что это работает для вас тоже. Инертная проблема. :) Приветствия!

Answer 4

Мне не удалось выделить/выделить текст в событии Enter, поскольку события mousedown и mouseup, следующие после этого, несколько сбрасывают выбор.

Я думаю, что самый правильный способ достижения того, что вы хотите, это:

' if you want to allow highlight more then once, reset the variable LastEntered prior to call SelectTboxText: 
'  LastEntered = "" 
'  SelectTboxText TextBox2 


Dim LastEntered As String 


' Button to select Textbox1 
Private Sub CommandButton1_Click() 
    SelectTboxText TextBox1 
End Sub 

' Button to select Textbox2 
Private Sub CommandButton2_Click() 
    SelectTboxText TextBox2 
End Sub 

Private Sub TextBox1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single) 
    SelectTboxText TextBox1 
End Sub 


Private Sub TextBox2_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single) 
    SelectTboxText TextBox2 
End Sub 


Public Sub SelectTboxText(ByRef tBox As MSForms.TextBox) 

    If LastEntered <> tBox.Name Then 

     LastEntered = tBox.Name 

     With tBox 
      .SetFocus 
      .SelStart = 0 
      .SelLength = Len(.Text) 
     End With 

    End If 

End Sub 

Таким образом, каждый раз, когда вы хотите, чтобы активировать один из текстового поля в программе, вы должны вызвать суб SelectTboxText, который не является действительно раздражает ИМО. В качестве примера я сделал 2 кнопки.

Answer 5

Поведение, которое вы пытаетесь реализовать, уже встроено в TextBox. Когда вы перемещаете мышь над левой стороной текстового поля, указатель мыши укажет вправо. Если вы нажмете, он выберет весь текст в поле. Щелчок в другом месте отменяет выбор текста.

Я попробую еще несколько стратегий, чтобы увидеть, могу ли я заставить это работать в одном Sub.

Answer 6

Это несколько улучшенный вариант что @vacip отправил. Вы получаете то, что вам не нужно добавлять отдельный модуль в модуль для каждого нового текстового поля.

Следующий код в форму пользователя:

'===== User Form Code ======== 

Option Explicit 

Private Sub TextBox1_Enter() 
    OnTextBoxEnter 
End Sub 

Private Sub TextBox2_Enter() 
    OnTextBoxEnter 
End Sub 

Private Sub TextBox3_Enter() 
    OnTextBoxEnter 
End Sub 

Следующий код идет в модуле:

'===== Module Code ======== 

Sub SelectAllText() 
    SendKeys "{HOME}+{END}", True 
End Sub 

Sub OnTextBoxEnter() 
    Application.OnTime Now + 0.00001, "SelectAllText", Now + 0.00002 
End Sub 

Answer 7

Попробуйте тот же код с TextBox1_MouseDown. Он должен работать.

Private Sub TextBox1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single) 
    With TextBox1 
     .SetFocus 
     .SelStart = 0 
     .SelLength = Len(.Text) 
    End With 
    MsgBox "Text in TextBox1 is selected" 
End Sub