Как удалить все файлы в папке, кроме 5 файлов

Question

Я хотел бы создать пакетный скрипт в Windows, чтобы удалить все файлы из папки, за исключением 5 конкретных файлов. Например, я хотел бы удалить все * .txt файлы, кроме файлов file1.txt, file2.txt, file3.txt, file4.txt и file5.txt.

Answer 1

Я попробовал следующую команду, и она работает. Test1.txt и test2.txt - это файл im, исключающий удаление. То, что он делает, это определить файл исключения в/и цикл через txt-файлы внутри папки. Это делается для обеспечения того, чтобы оно предназначалось только для файлов .txt.

@echo off 
setlocal EnableDelayedExpansion 
rem Add more names separated with slashes here: 
set exclude=/test1.txt/test2.txt/ 
for %%a in (*.txt) do (
    if "!exclude:/%%~a/=!" equ "%exclude%" (
     echo "Deleting" %%~a 
     del "%%~a" 
    ) 
) 

Коды адаптированы для этой темы - How do I exclude specific file names from an MS DOS dir list?. Я немного изменил, чтобы отобразить расширение файла (требуется для команды delete) и действие delete.

Answer 2

for %%f in (*.txt) do (
    if not %%f == file1.txt if not %%f == file2.txt if not %%f == file3.txt if not %%f == file4.txt if not %%f == file5.txt del %%f 
) 

Если вам не нравится смехотворно длинные командные строки, сделать

for %%f in (*.txt) do (
     if not %%f == file1.txt (
       if not %%f == file2.txt (
         if not %%f == file3.txt (
           if not %%f == file4.txt (
             if not %%f == file5.txt (
               del %%f 
     ))))) 
) 

Answer 3

Это будет работать - не запускать его в любой папке, кроме того, вы собираетесь:

@echo off 
for %%a in (1 2 3 4 5) do attrib +h "file%%a.txt" 
del *.*? 
for %%a in (1 2 3 4 5) do attrib -h "file%%a.txt" 

Answer 4

for /f "delims=" %%a in ('dir /a-d /b ^|findstr /xirv "file[1-5]\.txt"') do del "%%~a" 

Answer 5

md _emptyDir_ & robocopy _emptyDir_ . /purge /xf file1.txt file2.txt file3.txt file4.txt file5.txt 

Это создаст новый каталог (_emptyDir_) без файлов в нем , Затем robocopy используется для очистки текущего каталога файлов, отсутствующих в _emptyDir_. Поскольку в каталоге нет файлов, все файлы удаляются, за исключением файлов, указанных для исключения. Aditionaly, нет необходимости в rmdir _emptyDir_, поскольку robocopy также обработает его.

Чтобы использовать этот метод, чтобы удалить только файлы .txt в из каталога, сохраняя указанные файлы, синтаксис будет

md _emptyDir_ & robocopy _emptyDir_ . *.txt /purge /xf file1.txt file2.txt file3.txt file4.txt file5.txt 

Из пустого каталога в текущий каталог, процесс только * .txt файлов, удаление не все существующий в источнике (есть что-нибудь на нем), кроме исключенных файлов.

В этом случае, поскольку обрабатываются только файлы txt, _emptyDir_ не удаляется автоматически.

Answer 6

Удалить все * .txt файлы в папке ScanDir за исключением, file1.txt, file2.txt, file3.txt, file4.txt, file5.txt

@echo off 
@break off 
@title How to delete all files in a folder except 5 files - D3F4ULT 
@color 0a 
@cls 

setlocal EnableDelayedExpansion 

set "SCANDIR=D:\Batch\Stack Overflow\How to delete all files in a folder except 5 files\files" 

if not exist "!SCANDIR!\" echo ERROR&&echo.&&echo Folder not found = '%~nx1'&&echo.&&echo Exiting...&&echo.&&ping -n 8 localhost>nul&&exit /B 1 

for %%a in ("!SCANDIR!\*.txt") do (
    set "DEL_FILE_FLAG=Y" 
    if /I "%%~nxa" EQU "file1.txt" set "DEL_FILE_FLAG=N" 
    if /I "%%~nxa" EQU "file2.txt" set "DEL_FILE_FLAG=N" 
    if /I "%%~nxa" EQU "file3.txt" set "DEL_FILE_FLAG=N" 
    if /I "%%~nxa" EQU "file4.txt" set "DEL_FILE_FLAG=N" 
    if /I "%%~nxa" EQU "file5.txt" set "DEL_FILE_FLAG=N" 
    if defined DEL_FILE_FLAG if "!DEL_FILE_FLAG!" EQU "Y" (
    del /f /q "%%~dpnxa">nul 2>&1 
) 
) 

pause 
exit