Получите последний день в месяц в AppleScript и праздники в текущем месяце

Question

Я пишу AppleScript, который каждый месяц создает электронную таблицу MS Excel. Мне нужно знать, сколько дней в текущем месяце, а затем пройти через все месяцы и решить, является ли данный день рабочим днем ​​или праздником.

Я полагаю, что я бы сэкономил праздничные дни (из этой сети http://kalendar365.cz/statni-svatky/2016 в качестве таблицы и получить доступ к ним локально).

Мой вопрос:

1. Как получить последний день в течение месяца?
2. Как эффективно выполнять петлю через все дни текущего месяца и решать, будет ли это воскресенье, суббота или день, указанные где-то в другом месте (например, в текстовом файле таблицы xlsx)?

Answer 1

pbell's answer является перспективным, но функция GetLastDay не работает в течение нескольких месяцев, которые имеют меньше, чем 31 дней; вот функция, которая фиксирует, что:

# Returns the number of days in the month that the given date falls in. 
# Example: 
#  my GetNumberOfDaysInMonth(current date) 
on GetNumberOfDaysInMonth(aDate) 
    local aDateCopy 
    copy aDate to aDateCopy 
    set day of aDateCopy to 1 
    if month of aDateCopy is December then 
     set year of aDateCopy to ((year of aDateCopy) + 1) 
     set month of aDateCopy to 1 
    else 
     set month of aDateCopy to ((month of aDateCopy) + 1) 
    end if 
    return day of (aDateCopy - 1 * days) 
end GetNumberOfDaysInMonth 

Подход основан на установке даты на 1 месяц, затем увеличивающиеся месяц (возможно опрокидывание в следующем году), и вычитая 1 день, который работает правильно со всеми датами, даже в високосные годы.

Answer 2

Скрипт ниже содержит 2 подпрограммы, которые вы ищете: GetlastDay и isWorkingDay:

set myDate to current date -- just for example ! 

set N to GetlastDay(myDate) 
log N --> number of days in month of myDate 
set A to IsWorkingday(myDate) 
log A --> true if Monday to Friday, false if Saturday/Sunday 


on GetlastDay(LDate) -- return last day of month of LDate 
copy LDate to L -- to not change LDate 
set L's day to 32 -- = first day of next month 
set L to L - (1 * days) -- last day of month 
return day of L 
end GetlastDay 

on IsWorkingday(LDate) -- true if date is not Saturday or Sunday 
set SD to weekday of LDate 
return (SD is not in {Saturday, Sunday}) 
end IsWorkingday