Открыть URL-адрес на новой вкладке Safari с помощью AppleScript

Question

Возможно ли использовать AppleScript для открытия ссылки на новой вкладке в Safari?

Answer 1

Это будет работать:

tell application "Safari" 
    tell window 1 
     set current tab to (make new tab with properties {URL:"http://www.stackoverflow.com"}) 
    end tell 
end tell 

Answer 2

Код:

tell application "System Events" 
tell application "Safari" to activate 
tell process "Safari" 
click menu item "New Tab" of menu "File" of menu bar 1 
end tell 
end tell 

tell application "Safari" 
set URL of document 1 to "http://www.stackoverflow.com/" 
end tell 

Одна проблема заключается в том, что это работает только если языком системы является английский.

Answer 3

Это обычно должны создать новую вкладку и сфокусировать его (или фокус существующую вкладку, если URL уже открыт):

tell application "Safari" 
    open location "http://stackoverflow.com" 
    activate 
end tell 

Это открывает новый если «Открывать страницы в вкладках, а не в окнах» никогда не установлено.

tell application "System Events" to open location не работает с некоторыми URL-адресов, содержащих не-ASCII символы:

set u to "http://ja.wikipedia.org/wiki/漢字" 
tell application "System Events" to open location u 
--tell application "Safari" to open location u 
--do shell script "open " & quoted form of u 

Это открывает новую вкладку, даже если новые страницы планируется открыть в окнах:

tell application "Safari" 
    activate 
    reopen 
    tell (window 1 where (its document is not missing value)) 
     if name of its document is not "Untitled" then set current tab to (make new tab) 
     set index to 1 
    end tell 
    set URL of document 1 to "http://stackoverflow.com" 
end tell 
tell application "System Events" to tell process "Safari" 
    perform action "AXRaise" of window 1 
end tell 

set index to 1 не поднимает окно, но делает это окно как window 1 Системным событиям, которое может AXRaise.

Answer 4

Я использовал следующий скрипт, чтобы открыть сотни документов на вкладках в одном окне.

tell application "Safari" 
    tell window 1 
     make new tab with properties {URL:"http://foo.com/bar"} 
     make new tab with properties {URL:"http://foo.com/baz"} 
    end tell 
end tell 

Но это больше не работает в Safari 5.1 на Lion. Он откроет новую вкладку, но не будет загружать URL-адрес, указанный в glob свойства. Я изменил его к следующему, который сейчас работает:

tell application "Safari" 
    tell window 1 
     set URL of (make new tab) to "http://foo.com/bar" 
     set make new tab to "http://foo.com/baz" 
    end tell 
end tell 

Answer 5

Я думаю, что это также делает то, что вы просили, но гораздо короче и менее браузер конкретны:

do shell script "open http://www.webpagehere.com" 

Откроется указанный URL в вашем браузере по умолчанию. И если вы явно хотите, чтобы открыть его в Safari, используйте:

do shell script "open -a Safari 'http://www.webpagehere.com'" 

Answer 6

Я не могу комментировать: -/так что я отвечу, чтобы сказать, что ответ Тима (выше) работает на OS X 10.8.5. Это одна линия версия его сценария также работает:

tell window 1 of application "Safari" to set current tab to (make new tab with properties {URL:"http://www.stackoverflow.com"}) 

Arrgh - одна линия переполнен. Здесь без кода тегов:

СКАЖИТЕ окно 1 приложения «Сафари», чтобы установить текущую вкладку, чтобы (сделать новую вкладку со свойствами {URL: «http://www.stackoverflow.com»})

Answer 7

Я закончил с использованием Automator сделать это было намного проще, и это работает.

Answer 8

Прошло некоторое время, так как новый ответ был опубликован здесь. Я думаю, что это оптимальный способ сделать это. Он откроет Safari, если он не открыт, создайте новое окно, если нет открытых окон, и добавьте вкладку в текущее (или вновь созданное) окно.

tell application "Safari" 
    activate 
    try 
     tell window 1 to set current tab to make new tab with properties {URL:theURL} 
    on error 
     open location theURL 
    end try 
end tell 

Answer 9

Вы можете попробовать следующий подход:

Также и может сочетать использование Apple, сценарий в FastScript (бесплатно для 10 клавиш)

Чтобы добавить скрипт - просто сохранить сценарий в /Library/Scripts , После того, как вы сможете установить ярлык для нового скрипта.

Если вы хотите, чтобы открыть новое окно, чем новая вкладка и может играть в следующем:

tell application "System Events" 
    tell process "Safari" 
     click menu item "New window" of menu "File" of menu bar 1 
    end tell 
end tell 

Примечания: вам нужно разрешить использовать AppleScript specialCapabilities в настройках безопасности в данном случае.

Answer 10

Не кратчайшее решение, но и работает, а не только на английском языке ...

tell application "Safari" 
    activate 
end tell 

tell application "System Events" 
    set frontmost of process "Safari" to true 
    keystroke "t" using {command down} 
end tell 

set myURL to "anyurl.html" 
delay 2 
tell application "Safari" to set the URL of the front document to myURL 

Answer 11

Работал для меня в Safari v.11

tell application "Safari" 
    tell window 1 
     make new tab with properties {URL:"https://twitter.com"} 
    end tell 
end tell