Haxe - Как объявить переменную быть экземпляром родительского или дочернего класса

Question

Предположим, что у меня есть два класса:

class PlayerManagerParent { 
    public function new(){ 
    } 
} 

class GameManagerParent { 
    public var playerManager:PlayerManagerParent(); 

    public function new(){ 
    } 
} 

который я подклассы, как

class PlayerManagerChild extends PlayerManagerParent { 
    public function new(){ 
     super(); 
    } 

    public function someMethod(){ 
    } 
} 

class GameManagerChild extends GameManagerParent { 

    public function new(){ 
     super(); 
     this.playerManager = new PlayerManagerChild(); 
    } 
} 

Тогда я сделать экземпляр GameManagerChild и хотите получить доступ к someMethod():

var gameManager:GameManagerChild = new GameManagerChild(); 
gameManager.playerManager.someMethod(); 

, который я, конечно, не может сделать, так как gameManager.playerManager - тип playerManager:PlayerManagerParent, который не определяет someMethod(), а компилятор/typechecker дает мне ошибку.

Как я могу решить эту проблему без объявления someMethod() в родительском классе, или установка playerManager типа в Dynamic (который был бы вариант, но тогда я не могу перебрать Iterable полей в playerManager, например)?

Answer 1

Вы можете использовать ограниченного параметризированный типа этого:

class PlayerManagerParent { 
    public function new(){ 
    } 
} 

class GameManagerParent<T:PlayerManagerParent> { 
    public var playerManager:T; 

    public function new(){ 
    } 
} 

С этим, вы можете расширить, как это:

class PlayerManagerChild extends PlayerManagerParent { 
    public function new(){ 
     super(); 
    } 

    public function someMethod(){ 
    } 
} 

class GameManagerChild extends GameManagerParent<PlayerManagerChild> { 

    public function new(){ 
     super(); 
     this.playerManager = new PlayerManagerChild(); 
    } 
} 

, которая позволяет это сделать:

var child = new GameManagerChild(); 
child.playerManager.someMethod(); 

Примеры использования:
http://try.haxe.org/#21bfC

Смотрите также:
http://haxe.org/manual/type-system-type-parameters.html

Protip: Можно даже пометить его как @:generic, который может быть получить дополнительную производительность на некоторых платформах: http://haxe.org/manual/type-system-generic.html

Answer 2

Вы должны вероятно, используйте параметры типа, например:

class GameManagerParent<PM:PlayerManagerParent> { 
    public var playerManager : PM; 
} 

class GameManagerChild 
extends GameManagerParent<PlayerManagerChild> { 
    public function new() { 
     playerManager = new PlayerManagerChild(); 
    } 
}