проверка изменения VBA в определенном диапазоне ячеек

Question

мне нужна функция, которая проверяет, является ли конкретный диапазон ячеек в VBA был изменен:

Private Sub Worksheet_Change(ByVal Target As Range) 
    If Not Intersect(Target, Range("A9:J100")) Is Nothing Then 
     MsgBox Target.Address 
    End If 
End Sub 

Этого код работает, проблема: они изменили на одни и те же значения (бросить интернет-обновление). Как проверить, действительно ли обновленные значения ячеек изменились на новые? (Без проверки один за другим OFC)

Заранее спасибо

Answer 1

В этом небольшом примере мы сохранить память блока данных и таким образом можем проверить, если какое-либо значение фактически изменилось. Обратите внимание на то, что память была уменьшена выше субстанции, чтобы сделать ее статической:

Dim MemoryOfThingsPast() As Variant 
Dim init As Long 
Private Sub Worksheet_Change(ByVal Target As Range) 
    Dim Interesting As Range 
    Dim I As Long, J As Long, K As Long 
    Set Interesting = Range("A9:J100") 
    If init = 0 Then 
     MemoryOfThingsPast = Interesting 
     init = 1 
     Exit Sub 
    End If 
    If Intersect(Target, Interesting) Is Nothing Then Exit Sub 
    K = 1 
    For I = LBound(MemoryOfThingsPast, 1) To UBound(MemoryOfThingsPast, 1) 
     For J = LBound(MemoryOfThingsPast, 2) To UBound(MemoryOfThingsPast, 2) 
      v1 = Interesting(K) 
      v2 = MemoryOfThingsPast(I, J) 
      If v1 <> v2 Then 
       MsgBox "Cell " & Interesting(K).Address & " has really changed" 
      End If 
      K = K + 1 
     Next J 
    Next I 
    MemoryOfThingsPast = Interesting 
End Sub